utilities/keditbookmarks/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set(RELEASE_SERVICE_VERSION_MINOR "04")
0006 set(RELEASE_SERVICE_VERSION_MICRO "70")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(keditbookmarks VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 # ECM setup
0012 set(KF_MIN_VERSION "5.240.0")
0013 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0014 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0015
0016 set(QT_MIN_VERSION "6.5.0")
0017
0018 include(KDEInstallDirs)
0019 include(KDECMakeSettings)
0020 include(KDECompilerSettings NO_POLICY_SCOPE)
0021
0022 include(ECMInstallIcons)
0023 include(ECMSetupVersion)
0024 include(ECMAddTests)
0025 include(ECMQtDeclareLoggingCategory)
0026 include(FeatureSummary)
0027 include(ECMAddAppIcon)
0028 include(KDEGitCommitHooks)
0029 include(KDEClangFormat)
0030 include(ECMDeprecationSettings)
0031 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0032 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0033
0034 set(KEDITBOOKMARKS_VERSION "5.97.0")
0035
0036 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS Core)
0037 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0038     Codecs
0039     ConfigWidgets
0040     CoreAddons
0041     I18n
0042     KIO
0043     Bookmarks
0044     Parts
0045     WidgetsAddons
0046     WindowSystem
0047     IconThemes
0048 )
0049 find_package(KF6DocTools ${KF_MIN_VERSION})
0050 set_package_properties(KF6DocTools PROPERTIES DESCRIPTION
0051     "Tools to generate documentation"
0052     TYPE OPTIONAL
0053 )
0054 if(BUILD_TESTING)
0055     find_package(Qt6Test ${QT_REQUIRED_VERSION} CONFIG REQUIRED)
0056 endif()
0057
0058 ecm_set_disabled_deprecation_versions(QT 6.6
0059     KF 5.240.0
0060     )
0061
0062 if(NOT APPLE)
0063     find_package(X11)
0064     set(HAVE_X11 ${X11_FOUND})
0065     if (HAVE_X11)
0066         set_package_properties(X11 PROPERTIES TYPE OPTIONAL)
0067     endif()
0068 endif()
0069
0070 add_subdirectory(src)
0071 ki18n_install(po)
0072 if (KF6DocTools_FOUND)
0073     kdoctools_install(po)
0074     add_subdirectory(doc)
0075 endif()
0076
0077 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0078
0079 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)