Warning, /sdk/kompare/CMakeLists.txt is written in an unsupported language. File is not indexed. 

0001 cmake_minimum_required(VERSION 3.16)
0002 
0003 # Release Service version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set (RELEASE_SERVICE_VERSION_MINOR "04")
0006 set (RELEASE_SERVICE_VERSION_MICRO "70")
0007 set (RELEASE_SERVICE_COMPACT_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${RELEASE_SERVICE_VERSION_MICRO}")
0008 
0009 # Bump KOMPARE_BASE_VERSION once new features are added
0010 set(KOMPARE_BASE_VERSION "4.1")
0011 set(KOMPARE_VERSION "${KOMPARE_BASE_VERSION}.${RELEASE_SERVICE_COMPACT_VERSION}")
0012 
0013 project(Kompare VERSION ${KOMPARE_VERSION})
0014 
0015 set(QT_MIN_VERSION "5.15.2")
0016 set(KF_MIN_VERSION "5.100.0")
0017 
0018 find_package(ECM ${KF_MIN_VERSION} NO_MODULE REQUIRED)
0019 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0020 
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024 
0025 include(ECMInstallIcons)
0026 include(ECMAddAppIcon)
0027 include(ECMQtDeclareLoggingCategory)
0028 include(ECMSetupVersion)
0029 include(ECMDeprecationSettings)
0030 include(GenerateExportHeader)
0031 include(FeatureSummary)
0032 
0033 
0034 if (QT_MAJOR_VERSION STREQUAL "6")
0035     set(QT_MIN_VERSION "6.5.0")
0036     set(KF_MIN_VERSION "5.240.0")
0037     set(KF_MAJOR_VERSION "6")
0038 else()
0039     set(KF_MAJOR_VERSION "5")
0040 endif()
0041 
0042 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS
0043     Core
0044     PrintSupport
0045     Widgets
0046 )
0047 
0048 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0049     CoreAddons
0050     Codecs
0051     DocTools
0052     IconThemes
0053     JobWidgets
0054     Config
0055     Parts
0056     TextEditor
0057     WidgetsAddons
0058     I18n
0059 )
0060 
0061 find_package(LibKompareDiff2 5.4 CONFIG)
0062 set_package_properties(LibKompareDiff2 PROPERTIES
0063     TYPE REQUIRED
0064 )
0065 
0066 
0067 set(KOMPARE_LIB_VERSION 5)
0068 set(KOMPARE_LIB_SOVERSION 5)
0069 
0070 if (QT_MAJOR_VERSION STREQUAL "6")
0071     ecm_set_disabled_deprecation_versions(
0072         QT 6.5
0073         KF 5.239
0074         KOMPAREDIFF2 5.4
0075     )
0076 else()
0077     ecm_set_disabled_deprecation_versions(
0078         QT 5.15.2
0079         KF 5.100
0080         KOMPAREDIFF2 5.4
0081     )
0082 endif()
0083 
0084 # added by KDE_COMPILERSETTINGS_LEVEL 5.85.0
0085 remove_definitions(
0086     -DQT_NO_URL_CAST_FROM_STRING
0087 )
0088 
0089 add_subdirectory(doc)
0090 add_subdirectory(src)
0091 
0092 ki18n_install(po)
0093 kdoctools_install(po)
0094 
0095 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)