sdk/kompare/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 # Release Service version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set (RELEASE_SERVICE_VERSION_MINOR "07")
0006 set (RELEASE_SERVICE_VERSION_MICRO "70")
0007 set (RELEASE_SERVICE_COMPACT_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 # Bump KOMPARE_BASE_VERSION once new features are added
0010 set(KOMPARE_BASE_VERSION "4.1")
0011 set(KOMPARE_VERSION "${KOMPARE_BASE_VERSION}.${RELEASE_SERVICE_COMPACT_VERSION}")
0012
0013 project(Kompare VERSION ${KOMPARE_VERSION})
0014
0015 set(QT_MIN_VERSION "5.15.2")
0016 set(KF_MIN_VERSION "5.100.0")
0017
0018 find_package(ECM ${KF_MIN_VERSION} NO_MODULE REQUIRED)
0019 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0020
0021 if (QT_MAJOR_VERSION STREQUAL "6")
0022     set(QT_MIN_VERSION "6.5.0")
0023     set(KF_MIN_VERSION "5.240.0")
0024     set(KF_MAJOR_VERSION "6")
0025 else()
0026     set(KF_MAJOR_VERSION "5")
0027 endif()
0028
0029 include(KDEInstallDirs)
0030 include(KDECMakeSettings)
0031 include(KDECompilerSettings NO_POLICY_SCOPE)
0032
0033 include(ECMInstallIcons)
0034 include(ECMAddAppIcon)
0035 include(ECMQtDeclareLoggingCategory)
0036 include(ECMSetupVersion)
0037 include(ECMDeprecationSettings)
0038 include(GenerateExportHeader)
0039 include(FeatureSummary)
0040
0041 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS
0042     Core
0043     PrintSupport
0044     Widgets
0045 )
0046
0047 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0048     CoreAddons
0049     Codecs
0050     DocTools
0051     IconThemes
0052     JobWidgets
0053     Config
0054     Parts
0055     TextEditor
0056     WidgetsAddons
0057 )
0058
0059 find_package(LibKompareDiff2 5.2 CONFIG)
0060 set_package_properties(LibKompareDiff2 PROPERTIES
0061     TYPE REQUIRED
0062 )
0063
0064
0065 set(KOMPARE_LIB_VERSION 5)
0066 set(KOMPARE_LIB_SOVERSION 5)
0067
0068 ecm_set_disabled_deprecation_versions(
0069     QT 5.15.2
0070     KF 5.100
0071 )
0072
0073 # added by KDE_COMPILERSETTINGS_LEVEL 5.85.0
0074 remove_definitions(
0075     -DQT_NO_URL_CAST_FROM_STRING
0076 )
0077
0078 add_subdirectory(doc)
0079 add_subdirectory(src)
0080
0081 ki18n_install(po)
0082 kdoctools_install(po)
0083
0084 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)