Warning, /sdk/kompare/CMakeLists.txt is written in an unsupported language. File is not indexed. 

0001 cmake_minimum_required(VERSION 3.16)
0002 
0003 # Release Service version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set (RELEASE_SERVICE_VERSION_MINOR "04")
0006 set (RELEASE_SERVICE_VERSION_MICRO "70")
0007 set (RELEASE_SERVICE_COMPACT_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${RELEASE_SERVICE_VERSION_MICRO}")
0008 
0009 # Bump KOMPARE_BASE_VERSION once new features are added
0010 set(KOMPARE_BASE_VERSION "4.2")
0011 set(KOMPARE_VERSION "${KOMPARE_BASE_VERSION}.${RELEASE_SERVICE_COMPACT_VERSION}")
0012 
0013 project(Kompare VERSION ${KOMPARE_VERSION})
0014 
0015 set(QT_MIN_VERSION "6.5.0")
0016 set(KF_MIN_VERSION "5.240.0")
0017 
0018 find_package(ECM ${KF_MIN_VERSION} NO_MODULE REQUIRED)
0019 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0020 
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024 
0025 include(ECMInstallIcons)
0026 include(ECMAddAppIcon)
0027 include(ECMQtDeclareLoggingCategory)
0028 include(ECMSetupVersion)
0029 include(ECMDeprecationSettings)
0030 include(GenerateExportHeader)
0031 include(FeatureSummary)
0032 
0033 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS
0034     Core
0035     PrintSupport
0036     Widgets
0037 )
0038 
0039 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0040     CoreAddons
0041     Codecs
0042     DocTools
0043     IconThemes
0044     JobWidgets
0045     Config
0046     Parts
0047     TextEditor
0048     WidgetsAddons
0049     I18n
0050 )
0051 
0052 find_package(KompareDiff2 6.0 CONFIG)
0053 set_package_properties(KompareDiff2 PROPERTIES
0054     TYPE REQUIRED
0055 )
0056 
0057 
0058 set(KOMPARE_LIB_VERSION 6)
0059 set(KOMPARE_LIB_SOVERSION 6)
0060 
0061 ecm_set_disabled_deprecation_versions(
0062     QT 6.5
0063     KF 5.239
0064     KOMPAREDIFF2 5.4
0065 )
0066 
0067 # added by KDE_COMPILERSETTINGS_LEVEL 5.85.0
0068 remove_definitions(
0069     -DQT_NO_URL_CAST_FROM_STRING
0070 )
0071 
0072 add_subdirectory(doc)
0073 add_subdirectory(src)
0074 
0075 ki18n_install(po)
0076 kdoctools_install(po)
0077 
0078 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)