kdesvn/src/CMakeLists.txt

0001 ####
0002  #   Copyright (C) 2005-2009 by Rajko Albrecht  ral@alwins-world.de        #
0003  #   http://kdesvn.alwins-world.de/                                        #
0004  #                                                                         #
0005  #   This program is free software; you can redistribute it and/or modify  #
0006  #   it under the terms of the GNU General Public License as published by  #
0007  #   the Free Software Foundation; either version 2 of the License, or     #
0008  #   (at your option) any later version.                                   #
0009  #                                                                         #
0010  #   This program is distributed in the hope that it will be useful,       #
0011  #   but WITHOUT ANY WARRANTY; without even the implied warranty of        #
0012  #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         #
0013  #   GNU General Public License for more details.                          #
0014  #                                                                         #
0015  #   You should have received a copy of the GNU General Public License     #
0016  #   along with this program; if not, write to the                         #
0017  #   Free Software Foundation, Inc.,                                       #
0018  #   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         #
0019  ####
0020
0021 include(ECMMarkNonGuiExecutable)
0022 include(ECMAddAppIcon)
0023
0024 add_executable(kdesvnaskpass askpass/kdesvn-askpass.cpp)
0025 ecm_mark_nongui_executable(kdesvnaskpass)
0026
0027 ki18n_wrap_ui(kdesvn_ui
0028     urldlg.ui
0029 )
0030 set(kdesvnsrc
0031     commandline.cpp
0032     kdesvn.cpp
0033     main.cpp
0034     urldlg.cpp
0035 )
0036
0037 # Sets the icon on Windows and OSX
0038 find_program(KSVG2ICNS NAMES ksvg2icns)
0039 if(APPLE AND KSVG2ICNS)
0040     execute_process(COMMAND ${KSVG2ICNS} "${CMAKE_CURRENT_SOURCE_DIR}/icons/sc-apps-kdesvn.svgz"
0041          WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR} RESULT_VARIABLE KSVG2ICNS_ERROR)
0042     if(${KSVG2ICNS_ERROR})
0043         message(SEND_ERROR "Could not generate OS X application icon")
0044     else()
0045         set(MACOSX_BUNDLE_ICON_FILE sc-apps-kdesvn.icns)
0046         set(kdesvnsrc "${kdesvnsrc};${CMAKE_CURRENT_BINARY_DIR}/sc-apps-kdesvn.icns")
0047         set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/sc-apps-kdesvn.icns PROPERTIES MACOSX_PACKAGE_LOCATION Resources)
0048     endif()
0049 else()
0050     file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*-apps-kdesvn.png")
0051     ecm_add_app_icon(kdesvnsrc ICONS ${ICONS_SRCS})
0052 endif()
0053
0054 set(partsrc
0055     commandline_part.cpp
0056     kdesvn_part.cpp
0057     kdesvnview.cpp
0058 )
0059
0060 set(partsrc ${partsrc} kdesvn_part.h kdesvnview.h commandline_part.h)
0061 set(kdesvnsrc ${kdesvnsrc} ${kdesvn_ui} kdesvn.h urldlg.h commandline.h)
0062
0063 add_subdirectory(svnqt)
0064 add_subdirectory(ksvnwidgets)
0065 add_subdirectory(settings)
0066 add_subdirectory(svnfrontend)
0067 add_subdirectory(helpers)
0068 add_subdirectory(kdesvnd)
0069 add_subdirectory(kiosvn)
0070 add_subdirectory(pics)
0071 add_subdirectory(icons)
0072
0073 add_executable(kdesvn ${kdesvnsrc})
0074 add_library(kdesvnpart MODULE ${partsrc})
0075
0076 target_link_libraries(kdesvnpart
0077     svnfrontend
0078     kdesvnhelpers
0079     ksvnwidgets
0080     settingsdlgs
0081     kdesvncfgreader
0082     svnbackground
0083     svnqt
0084 )
0085
0086 set_target_properties(kdesvnpart
0087     PROPERTIES
0088     LINK_FLAGS "${APR_EXTRA_LDFLAGS} ${APU_EXTRA_LDFLAGS} ${LINK_NO_UNDEFINED}")
0089
0090 target_link_libraries(kdesvnaskpass
0091     KF5::CoreAddons
0092     KF5::I18n
0093     KF5::WidgetsAddons
0094     KF5::Wallet
0095 )
0096 target_link_libraries(kdesvn
0097     KF5::Parts
0098     KF5::Bookmarks
0099     kdesvnhelpers
0100 )
0101
0102 install(TARGETS kdesvn kdesvnaskpass kdesvnpart
0103     ${INSTALL_TARGETS_DEFAULT_ARGS}
0104     LIBRARY DESTINATION ${PLUGIN_INSTALL_DIR})
0105
0106 # the resources
0107 install(FILES kdesvnui.rc DESTINATION ${KXMLGUI_INSTALL_DIR}/kdesvn)
0108 install(FILES kdesvn_part.rc DESTINATION ${KXMLGUI_INSTALL_DIR}/kdesvn)
0109 install(FILES org.kde.kdesvn.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0110 install(FILES org.kde.kdesvn.desktop DESTINATION ${XDG_APPS_INSTALL_DIR})
0111 install(FILES kdesvnpart.desktop  DESTINATION ${SERVICES_INSTALL_DIR})
0112 install(FILES kdesvn.notifyrc DESTINATION ${DATA_INSTALL_DIR}/kdesvn)