Warning, /sdk/kdesvn/src/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 ####
0002  #   Copyright (C) 2005-2009 by Rajko Albrecht  ral@alwins-world.de        #
0003  #                                                                         #
0004  #   This program is free software; you can redistribute it and/or modify  #
0005  #   it under the terms of the GNU General Public License as published by  #
0006  #   the Free Software Foundation; either version 2 of the License, or     #
0007  #   (at your option) any later version.                                   #
0008  #                                                                         #
0009  #   This program is distributed in the hope that it will be useful,       #
0010  #   but WITHOUT ANY WARRANTY; without even the implied warranty of        #
0011  #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         #
0012  #   GNU General Public License for more details.                          #
0013  #                                                                         #
0014  #   You should have received a copy of the GNU General Public License     #
0015  #   along with this program; if not, write to the                         #
0016  #   Free Software Foundation, Inc.,                                       #
0017  #   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         #
0018  ####
0019 
0020 include(ECMMarkNonGuiExecutable)
0021 include(ECMAddAppIcon)
0022 
0023 add_executable(kdesvnaskpass askpass/kdesvn-askpass.cpp)
0024 ecm_mark_nongui_executable(kdesvnaskpass)
0025 
0026 ki18n_wrap_ui(kdesvn_ui
0027     urldlg.ui
0028 )
0029 set(kdesvnsrc
0030     commandline.cpp
0031     kdesvn.cpp
0032     main.cpp
0033     urldlg.cpp
0034 
0035     kdesvn.qrc
0036 )
0037 
0038 # Sets the icon on Windows and OSX
0039 find_program(KSVG2ICNS NAMES ksvg2icns)
0040 if(APPLE AND KSVG2ICNS)
0041     execute_process(COMMAND ${KSVG2ICNS} "${CMAKE_CURRENT_SOURCE_DIR}/icons/sc-apps-kdesvn.svgz"
0042          WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR} RESULT_VARIABLE KSVG2ICNS_ERROR)
0043     if(${KSVG2ICNS_ERROR})
0044         message(SEND_ERROR "Could not generate OS X application icon")
0045     else()
0046         set(MACOSX_BUNDLE_ICON_FILE sc-apps-kdesvn.icns)
0047         set(kdesvnsrc "${kdesvnsrc};${CMAKE_CURRENT_BINARY_DIR}/sc-apps-kdesvn.icns")
0048         set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/sc-apps-kdesvn.icns PROPERTIES MACOSX_PACKAGE_LOCATION Resources)
0049     endif()
0050 else()
0051     file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*-apps-kdesvn.png")
0052     ecm_add_app_icon(kdesvnsrc ICONS ${ICONS_SRCS})
0053 endif()
0054 
0055 set(partsrc
0056     kdesvn_part.cpp
0057     kdesvnview.cpp
0058 
0059     kdesvn_part.qrc
0060 )
0061 
0062 set(partsrc ${partsrc} kdesvn_part.h kdesvnview.h)
0063 set(kdesvnsrc ${kdesvnsrc} ${kdesvn_ui} kdesvn.h urldlg.h commandline.h)
0064 
0065 add_subdirectory(svnqt)
0066 add_subdirectory(ksvnwidgets)
0067 add_subdirectory(settings)
0068 add_subdirectory(svnfrontend)
0069 add_subdirectory(helpers)
0070 add_subdirectory(kdesvnd)
0071 add_subdirectory(kiosvn)
0072 add_subdirectory(pics)
0073 add_subdirectory(icons)
0074 add_subdirectory(fileitemactions)
0075 
0076 add_executable(kdesvn ${kdesvnsrc})
0077 
0078 kcoreaddons_add_plugin(kdesvnpart SOURCES ${partsrc} INSTALL_NAMESPACE "kf5/parts")
0079 
0080 kcoreaddons_desktop_to_json(kdesvnpart kdesvnpart.desktop)
0081 
0082 target_link_libraries(kdesvnpart
0083     svnfrontend
0084     kdesvnhelpers
0085     ksvnwidgets
0086     settingsdlgs
0087     kdesvncfgreader
0088     svnbackground
0089     svnqt
0090 )
0091 
0092 set_target_properties(kdesvnpart
0093     PROPERTIES
0094     LINK_FLAGS "${APR_EXTRA_LDFLAGS} ${APU_EXTRA_LDFLAGS} ${LINK_NO_UNDEFINED}")
0095 
0096 target_link_libraries(kdesvnaskpass
0097     KF5::CoreAddons
0098     KF5::I18n
0099     KF5::WidgetsAddons
0100     KF5::Wallet
0101 )
0102 target_link_libraries(kdesvn
0103     KF5::Parts
0104     KF5::Bookmarks
0105     kdesvnhelpers
0106     svnfrontend
0107     svnbackground
0108 )
0109 
0110 install(TARGETS kdesvn kdesvnaskpass
0111     ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0112 
0113 # the resources
0114 install(FILES org.kde.kdesvn.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0115 install(FILES org.kde.kdesvn.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0116 install(FILES kdesvnpart.desktop  DESTINATION ${KDE_INSTALL_KSERVICESDIR})
0117 install(FILES kdesvn.notifyrc DESTINATION ${KDE_INSTALL_DATADIR}/kdesvn)