plasma-workspace/libtaskmanager/CMakeLists.txt

0001 add_subdirectory(declarative)
0002 if(BUILD_TESTING)
0003    add_subdirectory(autotests)
0004 endif()
0005
0006 set(taskmanager_LIB_SRCS
0007     abstracttasksmodel.cpp
0008     abstracttasksproxymodeliface.cpp
0009     abstractwindowtasksmodel.cpp
0010     activityinfo.cpp
0011     concatenatetasksproxymodel.cpp
0012     flattentaskgroupsproxymodel.cpp
0013     launchertasksmodel.cpp
0014     startuptasksmodel.cpp
0015     taskfilterproxymodel.cpp
0016     taskgroupingproxymodel.cpp
0017     tasksmodel.cpp
0018     tasktools.cpp
0019     virtualdesktopinfo.cpp
0020     waylandstartuptasksmodel.cpp
0021     waylandtasksmodel.cpp
0022     windowtasksmodel.cpp
0023 )
0024
0025 if (HAVE_X11)
0026     set(taskmanager_LIB_SRCS
0027         ${taskmanager_LIB_SRCS}
0028         xstartuptasksmodel.cpp
0029         xwindowsystemeventbatcher.cpp
0030         xwindowtasksmodel.cpp
0031     )
0032 endif()
0033
0034 add_library(taskmanager ${taskmanager_LIB_SRCS})
0035 add_library(PW::LibTaskManager ALIAS taskmanager)
0036
0037 generate_export_header(taskmanager)
0038
0039 target_include_directories(taskmanager PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>" "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/taskmanager>")
0040
0041 target_link_libraries(taskmanager
0042     PUBLIC
0043         Qt::Core
0044         Qt::Gui
0045         Qt::Quick
0046         KF5::ItemModels
0047     PRIVATE
0048         Qt::DBus
0049         KF5::Activities
0050         KF5::ConfigCore
0051         KF5::I18n
0052         KF5::KIOCore
0053         KF5::KIOGui
0054         KF5::Notifications
0055         KF5::WaylandClient
0056         KF5::WindowSystem
0057 )
0058
0059 if (HAVE_X11)
0060     target_link_libraries(taskmanager PRIVATE KF5::IconThemes)
0061     if (QT_MAJOR_VERSION EQUAL "5")
0062         target_link_libraries(taskmanager PRIVATE Qt::X11Extras)
0063     else()
0064         target_link_libraries(taskmanager PRIVATE Qt::GuiPrivate)
0065     endif()
0066 endif()
0067
0068 set_target_properties(taskmanager PROPERTIES
0069                       VERSION ${PROJECT_VERSION}
0070                       SOVERSION 6
0071                       EXPORT_NAME LibTaskManager)
0072
0073
0074 ecm_qt_declare_logging_category(taskmanager
0075     HEADER libtaskmanager_debug.h
0076     IDENTIFIER TASKMANAGER_DEBUG
0077     CATEGORY_NAME org.kde.plasma.libtaskmanager
0078 )
0079
0080 install(TARGETS taskmanager EXPORT libtaskmanagerLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0081
0082 install(FILES
0083     abstracttasksmodel.h
0084     abstracttasksmodeliface.h
0085     abstracttasksproxymodeliface.h
0086     abstractwindowtasksmodel.h
0087     activityinfo.h
0088     concatenatetasksproxymodel.h
0089     flattentaskgroupsproxymodel.h
0090     launchertasksmodel.h
0091     startuptasksmodel.h
0092     taskfilterproxymodel.h
0093     taskgroupingproxymodel.h
0094     tasksmodel.h
0095     tasktools.h
0096     virtualdesktopinfo.h
0097     waylandstartuptasksmodel.h
0098     waylandtasksmodel.h
0099     windowtasksmodel.h
0100     ${CMAKE_CURRENT_BINARY_DIR}/taskmanager_export.h
0101     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/taskmanager COMPONENT Devel
0102 )
0103
0104 if (HAVE_X11)
0105     install(FILES
0106         xstartuptasksmodel.h
0107         xwindowtasksmodel.h
0108         DESTINATION ${KDE_INSTALL_INCLUDEDIR}/taskmanager COMPONENT Devel
0109     )
0110 endif()
0111
0112 write_basic_config_version_file(${CMAKE_CURRENT_BINARY_DIR}/LibTaskManagerConfigVersion.cmake VERSION "${PROJECT_VERSION}" COMPATIBILITY AnyNewerVersion)
0113
0114 set(CMAKECONFIG_INSTALL_DIR ${KDE_INSTALL_CMAKEPACKAGEDIR}/LibTaskManager)
0115
0116 configure_package_config_file(LibTaskManagerConfig.cmake.in
0117     "${CMAKE_CURRENT_BINARY_DIR}/LibTaskManagerConfig.cmake"
0118     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0119
0120 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/LibTaskManagerConfig.cmake
0121               ${CMAKE_CURRENT_BINARY_DIR}/LibTaskManagerConfigVersion.cmake
0122         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0123
0124 install(EXPORT libtaskmanagerLibraryTargets
0125         NAMESPACE PW::
0126         DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0127         FILE LibTaskManagerLibraryTargets.cmake )
0128
0129 install(FILES taskmanagerrulesrc
0130         DESTINATION ${KDE_INSTALL_CONFDIR})