plasma-workspace/libtaskmanager/CMakeLists.txt

0001 add_subdirectory(declarative)
0002 if(BUILD_TESTING)
0003    add_subdirectory(autotests)
0004 endif()
0005
0006 set(taskmanager_LIB_SRCS
0007     abstracttasksmodel.cpp
0008     abstracttasksproxymodeliface.cpp
0009     abstractwindowtasksmodel.cpp
0010     activityinfo.cpp
0011     concatenatetasksproxymodel.cpp
0012     flattentaskgroupsproxymodel.cpp
0013     launchertasksmodel.cpp
0014     startuptasksmodel.cpp
0015     regionfiltermode.h
0016     taskfilterproxymodel.cpp
0017     taskgroupingproxymodel.cpp
0018     tasksmodel.cpp
0019     tasktools.cpp
0020     virtualdesktopinfo.cpp
0021     waylandstartuptasksmodel.cpp
0022     waylandtasksmodel.cpp
0023     windowtasksmodel.cpp
0024 )
0025
0026 if (HAVE_X11)
0027     set(taskmanager_LIB_SRCS
0028         ${taskmanager_LIB_SRCS}
0029         xstartuptasksmodel.cpp
0030         xwindowsystemeventbatcher.cpp
0031         xwindowtasksmodel.cpp
0032     )
0033 endif()
0034
0035 add_library(taskmanager ${taskmanager_LIB_SRCS})
0036 add_library(PW::LibTaskManager ALIAS taskmanager)
0037
0038
0039 qt6_generate_wayland_protocol_client_sources(taskmanager
0040     FILES ${PLASMA_WAYLAND_PROTOCOLS_DIR}/org-kde-plasma-virtual-desktop.xml
0041     FILES ${PLASMA_WAYLAND_PROTOCOLS_DIR}/plasma-window-management.xml
0042 )
0043
0044 generate_export_header(taskmanager)
0045
0046 target_include_directories(taskmanager PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>" "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/taskmanager>")
0047
0048 target_link_libraries(taskmanager
0049     PUBLIC
0050         Qt::Core
0051         Qt::Gui
0052         Qt::Quick
0053         KF6::ItemModels
0054     PRIVATE
0055         Qt::Concurrent
0056         Qt::DBus
0057         Qt::GuiPrivate
0058         Qt::WaylandClient
0059         Plasma::Activities
0060         KF6::ConfigCore
0061         KF6::I18n
0062         KF6::KIOCore
0063         KF6::KIOGui
0064         KF6::JobWidgets
0065         KF6::Service
0066         KF6::WindowSystem
0067         PW::KWorkspace
0068 )
0069
0070 if (HAVE_X11)
0071     target_link_libraries(taskmanager PRIVATE KF6::IconThemes)
0072     target_link_libraries(taskmanager PRIVATE X11::X11)
0073 endif()
0074
0075 set_target_properties(taskmanager PROPERTIES
0076                       VERSION ${PROJECT_VERSION}
0077                       SOVERSION 6
0078                       EXPORT_NAME LibTaskManager)
0079
0080
0081 ecm_qt_declare_logging_category(taskmanager
0082     HEADER libtaskmanager_debug.h
0083     IDENTIFIER TASKMANAGER_DEBUG
0084     CATEGORY_NAME org.kde.plasma.libtaskmanager
0085     DESCRIPTION "libtaskmanager debug"
0086     EXPORT PLASMAWORKSPACE
0087 )
0088
0089 install(TARGETS taskmanager EXPORT libtaskmanagerLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0090
0091 install(FILES
0092     abstracttasksmodel.h
0093     abstracttasksmodeliface.h
0094     abstracttasksproxymodeliface.h
0095     abstractwindowtasksmodel.h
0096     activityinfo.h
0097     concatenatetasksproxymodel.h
0098     flattentaskgroupsproxymodel.h
0099     launchertasksmodel.h
0100     regionfiltermode.h
0101     startuptasksmodel.h
0102     taskfilterproxymodel.h
0103     taskgroupingproxymodel.h
0104     tasksmodel.h
0105     tasktools.h
0106     virtualdesktopinfo.h
0107     waylandstartuptasksmodel.h
0108     waylandtasksmodel.h
0109     windowtasksmodel.h
0110     ${CMAKE_CURRENT_BINARY_DIR}/taskmanager_export.h
0111     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/taskmanager COMPONENT Devel
0112 )
0113
0114 if (HAVE_X11)
0115     install(FILES
0116         xstartuptasksmodel.h
0117         xwindowtasksmodel.h
0118         DESTINATION ${KDE_INSTALL_INCLUDEDIR}/taskmanager COMPONENT Devel
0119     )
0120 endif()
0121
0122 write_basic_config_version_file(${CMAKE_CURRENT_BINARY_DIR}/LibTaskManagerConfigVersion.cmake VERSION "${PROJECT_VERSION}" COMPATIBILITY AnyNewerVersion)
0123
0124 set(CMAKECONFIG_INSTALL_DIR ${KDE_INSTALL_CMAKEPACKAGEDIR}/LibTaskManager)
0125
0126 configure_package_config_file(LibTaskManagerConfig.cmake.in
0127     "${CMAKE_CURRENT_BINARY_DIR}/LibTaskManagerConfig.cmake"
0128     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0129
0130 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/LibTaskManagerConfig.cmake
0131               ${CMAKE_CURRENT_BINARY_DIR}/LibTaskManagerConfigVersion.cmake
0132         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0133
0134 install(EXPORT libtaskmanagerLibraryTargets
0135         NAMESPACE PW::
0136         DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0137         FILE LibTaskManagerLibraryTargets.cmake )
0138
0139 install(FILES taskmanagerrulesrc
0140         DESTINATION ${KDE_INSTALL_CONFDIR})