plasma-workspace/libcolorcorrect/CMakeLists.txt

0001 add_subdirectory(declarative)
0002 add_subdirectory(kded)
0003
0004 set(colorcorrect_LIB_SRCS
0005     compositorcoloradaptor.cpp
0006     geolocator.cpp
0007     suncalc.cpp
0008     )
0009
0010 add_library(colorcorrect ${colorcorrect_LIB_SRCS})
0011 add_library(PW::LibColorCorrect ALIAS colorcorrect)
0012
0013 generate_export_header(colorcorrect)
0014
0015 target_include_directories(colorcorrect PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>" "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/colorcorrect>")
0016
0017 target_link_libraries(colorcorrect
0018                     PUBLIC
0019                       KF5::Plasma
0020
0021                       Qt::Core
0022                       Qt::Quick
0023                     PRIVATE
0024                       KF5::I18n
0025
0026                       Qt::DBus)
0027
0028 set_target_properties(colorcorrect PROPERTIES
0029                       VERSION ${PROJECT_VERSION}
0030                       SOVERSION ${PROJECT_VERSION_MAJOR}
0031                       EXPORT_NAME LibColorCorrect)
0032
0033 install(TARGETS colorcorrect EXPORT libcolorcorrectLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0034
0035 install(FILES
0036     colorcorrectconstants.h
0037     compositorcoloradaptor.h
0038     geolocator.h
0039     ${CMAKE_CURRENT_BINARY_DIR}/colorcorrect_export.h
0040     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/colorcorrect COMPONENT Devel
0041 )
0042
0043 write_basic_config_version_file(${CMAKE_CURRENT_BINARY_DIR}/LibColorCorrectConfigVersion.cmake VERSION "${PROJECT_VERSION}" COMPATIBILITY AnyNewerVersion)
0044
0045 set(CMAKECONFIG_INSTALL_DIR ${KDE_INSTALL_CMAKEPACKAGEDIR}/LibColorCorrect)
0046
0047 configure_package_config_file(LibColorCorrectConfig.cmake.in
0048     "${CMAKE_CURRENT_BINARY_DIR}/LibColorCorrectConfig.cmake"
0049     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0050
0051 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/LibColorCorrectConfig.cmake
0052               ${CMAKE_CURRENT_BINARY_DIR}/LibColorCorrectConfigVersion.cmake
0053         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0054
0055 install(EXPORT libcolorcorrectLibraryTargets
0056         NAMESPACE PW::
0057         DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0058         FILE LibColorCorrectLibraryTargets.cmake )