plasma-workspace/libcolorcorrect/CMakeLists.txt

0001 add_subdirectory(kded)
0002
0003 set(colorcorrect_LIB_SRCS
0004     compositorcoloradaptor.cpp
0005     geolocator.cpp
0006     suncalc.cpp
0007     )
0008
0009 add_library(colorcorrect ${colorcorrect_LIB_SRCS})
0010 add_library(PW::LibColorCorrect ALIAS colorcorrect)
0011
0012 generate_export_header(colorcorrect)
0013
0014 target_include_directories(colorcorrect PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>" "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/colorcorrect>")
0015
0016 target_link_libraries(colorcorrect
0017                     PUBLIC
0018                       Plasma::Plasma5Support
0019                       KF6::ConfigCore
0020
0021                       Qt::Core
0022                       Qt::Quick
0023                     PRIVATE
0024                       KF6::I18n
0025
0026                       Qt::DBus)
0027
0028 set_target_properties(colorcorrect PROPERTIES
0029                       VERSION ${PROJECT_VERSION}
0030                       SOVERSION ${PROJECT_VERSION_MAJOR}
0031                       EXPORT_NAME LibColorCorrect)
0032
0033 ecm_add_qml_module(colorcorrect URI org.kde.colorcorrect GENERATE_PLUGIN_SOURCE)
0034 ecm_finalize_qml_module(colorcorrect)
0035
0036 install(TARGETS colorcorrect EXPORT libcolorcorrectLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0037
0038 install(FILES
0039     colorcorrectconstants.h
0040     compositorcoloradaptor.h
0041     geolocator.h
0042     ${CMAKE_CURRENT_BINARY_DIR}/colorcorrect_export.h
0043     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/colorcorrect COMPONENT Devel
0044 )
0045
0046 write_basic_config_version_file(${CMAKE_CURRENT_BINARY_DIR}/LibColorCorrectConfigVersion.cmake VERSION "${PROJECT_VERSION}" COMPATIBILITY AnyNewerVersion)
0047
0048 set(CMAKECONFIG_INSTALL_DIR ${KDE_INSTALL_CMAKEPACKAGEDIR}/LibColorCorrect)
0049
0050 configure_package_config_file(LibColorCorrectConfig.cmake.in
0051     "${CMAKE_CURRENT_BINARY_DIR}/LibColorCorrectConfig.cmake"
0052     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0053
0054 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/LibColorCorrectConfig.cmake
0055               ${CMAKE_CURRENT_BINARY_DIR}/LibColorCorrectConfigVersion.cmake
0056         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0057
0058 install(EXPORT libcolorcorrectLibraryTargets
0059         NAMESPACE PW::
0060         DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0061         FILE LibColorCorrectLibraryTargets.cmake )