kcms/fonts/CMakeLists.txt

0001 # KI18N Translation Domain for this library
0002 add_definitions(-DTRANSLATION_DOMAIN=\"kcm_fonts\")
0003
0004 ########### next target ###############
0005
0006 add_library(kcm_fonts_static STATIC kxftconfig.cpp)
0007 target_link_libraries(kcm_fonts_static Qt::Xml KF5::I18n KF5::WindowSystem KF5::KCMUtils KF5::QuickAddons KF5::Declarative kfontinst krdb)
0008
0009 set_property(TARGET kcm_fonts_static PROPERTY POSITION_INDEPENDENT_CODE ON)
0010
0011 if(HAVE_X11)
0012     target_link_libraries(kcm_fonts_static X11::X11 X11::Xft XCB::IMAGE)
0013     if (QT_MAJOR_VERSION EQUAL "5")
0014         target_link_libraries(kcm_fonts_static Qt::X11Extras)
0015     else()
0016         target_link_libraries(kcm_fonts_static Qt::GuiPrivate)
0017     endif()
0018 endif()
0019
0020 set(kcm_fonts_PART_SRCS
0021     previewrenderengine.cpp
0022     previewimageprovider.cpp
0023     fonts.cpp
0024     fontsaasettings.cpp
0025     fontinit.cpp
0026     ../kfontinst/lib/FcEngine.cpp
0027     ../kcms-common.cpp
0028 )
0029
0030 kcmutils_generate_module_data(
0031     kcm_fonts_PART_SRCS
0032     MODULE_DATA_HEADER fontsdata.h
0033     MODULE_DATA_CLASS_NAME FontsData
0034     SETTINGS_HEADERS fontssettings.h fontsaasettings.h
0035     SETTINGS_CLASSES FontsSettings FontsAASettings
0036 )
0037
0038 kconfig_add_kcfg_files(kcm_fonts_PART_SRCS fontssettings.kcfgc fontsaasettingsbase.kcfgc GENERATE_MOC)
0039 kcoreaddons_add_plugin(kcm_fonts SOURCES ${kcm_fonts_PART_SRCS} INSTALL_NAMESPACE "plasma/kcms/systemsettings")
0040 kcmutils_generate_desktop_file (kcm_fonts)
0041
0042 target_link_libraries(kcm_fonts kcm_fonts_static)
0043
0044 ########### install files ###############
0045 install(FILES fontssettings.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0046 kpackage_install_package(package kcm_fonts kcms)
0047
0048 add_custom_command(TARGET kcm_fonts POST_BUILD
0049                    COMMAND ${CMAKE_COMMAND} -E create_symlink ../kcms/systemsettings/kcm_fonts.so kcm_fonts_init.so)
0050
0051 install( FILES ${CMAKE_CURRENT_BINARY_DIR}/kcm_fonts_init.so DESTINATION ${KDE_INSTALL_PLUGINDIR}/plasma/kcminit)
0052
0053 if (BUILD_TESTING)
0054    add_subdirectory(autotests)
0055 endif()