kcms/fonts/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kcm_fonts\")
0002
0003 ########### next target ###############
0004
0005 add_library(kcm_fonts_static STATIC kxftconfig.cpp)
0006 target_link_libraries(kcm_fonts_static Qt::Core Qt::Xml KF6::I18n KF6::WindowSystem KF6::KCMUtils KF6::KCMUtilsQuick kfontinst krdb)
0007
0008 set_property(TARGET kcm_fonts_static PROPERTY POSITION_INDEPENDENT_CODE ON)
0009
0010 if(HAVE_X11)
0011     target_link_libraries(kcm_fonts_static X11::X11 X11::Xft XCB::IMAGE Qt::GuiPrivate)
0012 endif()
0013
0014 kcmutils_add_qml_kcm(kcm_fonts)
0015 target_sources(kcm_fonts PRIVATE
0016     previewrenderengine.cpp
0017     previewimageprovider.cpp
0018     fonts.cpp
0019     fontsaasettings.cpp
0020     fontinit.cpp
0021     ../kfontinst/lib/FcEngine.cpp
0022     ../kcms-common.cpp
0023 )
0024
0025 kcmutils_generate_module_data(kcm_fonts
0026     MODULE_DATA_HEADER fontsdata.h
0027     MODULE_DATA_CLASS_NAME FontsData
0028     SETTINGS_HEADERS fontssettings.h fontsaasettings.h
0029     SETTINGS_CLASSES FontsSettings FontsAASettings
0030 )
0031 kconfig_add_kcfg_files(kcm_fonts fontssettings.kcfgc fontsaasettingsbase.kcfgc GENERATE_MOC)
0032
0033 target_link_libraries(kcm_fonts PRIVATE Qt::Quick kcm_fonts_static)
0034
0035 ########### install files ###############
0036 install(FILES fontssettings.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0037
0038 add_custom_command(TARGET kcm_fonts POST_BUILD
0039                    COMMAND ${CMAKE_COMMAND} -E create_symlink ../kcms/systemsettings/kcm_fonts.so kcm_fonts_init.so)
0040
0041 install( FILES ${CMAKE_CURRENT_BINARY_DIR}/kcm_fonts_init.so DESTINATION ${KDE_INSTALL_PLUGINDIR}/plasma/kcminit)
0042
0043 add_subdirectory(kconf_update)
0044
0045 if (BUILD_TESTING)
0046    add_subdirectory(autotests)
0047 endif()