plasma-disks/src/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: 2020-2021 Harald Sitter <sitter@kde.org>
0003
0004 add_definitions(-DTRANSLATION_DOMAIN=\"kcm_disks\")
0005
0006 set(kded_SRCS
0007     smartdata.cpp smartdata.h
0008     smartmonitor.cpp smartmonitor.h
0009     smartctl.cpp smartctl.h
0010     smartnotifier.cpp smartnotifier.h
0011     dbusobjectmanagerserver.cpp
0012     device.cpp
0013     devicenotifier.cpp
0014     soliddevicenotifier.cpp soliddevicenotifier.h
0015     instabilities.cpp instabilities.h
0016     smartfailure.cpp smartfailure.h
0017 )
0018
0019 if(WITH_SIMULATION)
0020     list(APPEND kded_SRCS
0021         simulationdevicenotifier.cpp simulationdevicenotifier.h
0022         simulationctl.cpp simulationctl.h
0023         ../autotests/fixtures/simulation.qrc)
0024     add_definitions(-DWITH_SIMULATION)
0025 endif()
0026
0027 ecm_qt_declare_logging_category(
0028     kded_SRCS
0029     HEADER "kded_debug.h"
0030     IDENTIFIER "KDED"
0031     CATEGORY_NAME "org.kde.plasma.disks"
0032     DESCRIPTION "Plasma Disks"
0033     EXPORT PlasmaDisks
0034 )
0035
0036 add_library(statickdedsmart STATIC ${kded_SRCS})
0037 set_property(TARGET statickdedsmart PROPERTY POSITION_INDEPENDENT_CODE ON)
0038 target_include_directories(statickdedsmart
0039     PUBLIC
0040         "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR};${CMAKE_CURRENT_BINARY_DIR}>")
0041 target_link_libraries(statickdedsmart
0042     PUBLIC
0043     Qt6::Core
0044     Qt6::DBus
0045     KF6::Solid
0046     KF6::I18n
0047     KF6::Notifications
0048     KF6::CoreAddons
0049     KF6::DBusAddons
0050     KF6::Service
0051     KF6::KIOGui
0052     KF6::AuthCore
0053 )
0054
0055 add_library(kded-smart MODULE main.cpp)
0056 set_target_properties(kded-smart PROPERTIES OUTPUT_NAME smart)
0057 target_link_libraries(kded-smart statickdedsmart)
0058 install(TARGETS kded-smart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/kded)
0059
0060 kauth_install_actions(org.kde.kded.smart org.kde.kded.smart.actions)
0061 add_executable(kded-smart-helper helper.cpp)
0062 target_link_libraries(kded-smart-helper KF6::AuthCore KF6::ConfigCore KF6::I18n)
0063
0064 kauth_install_helper_files(kded-smart-helper org.kde.kded.smart root)
0065 install(TARGETS kded-smart-helper DESTINATION ${KAUTH_HELPER_INSTALL_DIR})
0066
0067 install(FILES org.kde.kded.smart.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFYRCDIR})
0068
0069 add_subdirectory(kcm)