plasma-disks/src/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: 2020-2021 Harald Sitter <sitter@kde.org>
0003
0004 add_definitions(-DTRANSLATION_DOMAIN=\"plasma_disks\")
0005
0006 set(kded_SRCS
0007     smartdata.cpp
0008     smartmonitor.cpp
0009     smartctl.cpp
0010     smartnotifier.cpp
0011     dbusobjectmanagerserver.cpp
0012     device.cpp
0013     devicenotifier.cpp
0014     soliddevicenotifier.cpp
0015     instabilities.cpp
0016     smartfailure.cpp
0017 )
0018
0019 if(WITH_SIMULATION)
0020     list(APPEND kded_SRCS
0021         simulationdevicenotifier.cpp
0022         simulationctl.cpp
0023         ../autotests/fixtures/simulation.qrc)
0024     add_definitions(-DWITH_SIMULATION)
0025 endif()
0026
0027 ecm_qt_declare_logging_category(
0028     kded_SRCS
0029     HEADER "kded_debug.h"
0030     IDENTIFIER "KDED"
0031     CATEGORY_NAME "org.kde.plasma.disks"
0032     DESCRIPTION "Plasma Disks"
0033     EXPORT PlasmaDisks
0034 )
0035
0036 add_library(statickdedsmart STATIC ${kded_SRCS})
0037 set_property(TARGET statickdedsmart PROPERTY POSITION_INDEPENDENT_CODE ON)
0038 target_include_directories(statickdedsmart
0039     PUBLIC
0040         "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR};${CMAKE_CURRENT_BINARY_DIR}>")
0041 target_link_libraries(statickdedsmart
0042     PUBLIC
0043     Qt${QT_MAJOR_VERSION}::Core
0044     Qt${QT_MAJOR_VERSION}::DBus
0045     KF5::Solid
0046     KF5::I18n
0047     KF5::Notifications
0048     KF5::CoreAddons
0049     KF5::DBusAddons
0050     KF5::Service
0051     KF5::KIOGui
0052     KF5::AuthCore
0053 )
0054
0055 add_library(kded-smart MODULE main.cpp)
0056 kcoreaddons_desktop_to_json(kded-smart smart.desktop)
0057 set_target_properties(kded-smart PROPERTIES OUTPUT_NAME smart)
0058 target_link_libraries(kded-smart statickdedsmart)
0059 install(TARGETS kded-smart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf${QT_MAJOR_VERSION}/kded)
0060
0061 kauth_install_actions(org.kde.kded.smart org.kde.kded.smart.actions)
0062 add_executable(kded-smart-helper helper.cpp)
0063 target_link_libraries(kded-smart-helper KF5::AuthCore KF5::ConfigCore KF5::I18n)
0064
0065 kauth_install_helper_files(kded-smart-helper org.kde.kded.smart root)
0066 install(TARGETS kded-smart-helper DESTINATION ${KAUTH_HELPER_INSTALL_DIR})
0067
0068 install(FILES org.kde.kded.smart.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFYRCDIR})
0069
0070 add_subdirectory(kcm)