libplasma/autotests/CMakeLists.txt

0001 find_package(Qt${QT_MAJOR_VERSION}Test ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0002 set_package_properties(Qt${QT_MAJOR_VERSION}Test PROPERTIES PURPOSE "Required for tests")
0003
0004 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_BINARY_DIR})
0005 remove_definitions(-DQT_NO_CAST_FROM_ASCII -DQT_STRICT_ITERATORS -DQT_NO_CAST_FROM_BYTEARRAY -DQT_NO_KEYWORDS)
0006
0007 include(ECMMarkAsTest)
0008 include(ECMAddTests)
0009
0010 find_package(KF5CoreAddons REQUIRED)
0011 find_package(KF5XmlGui REQUIRED)
0012 find_package(Qt${QT_MAJOR_VERSION}Widgets REQUIRED)
0013
0014 # add_definitions( -DKDESRCDIR=${CMAKE_CURRENT_SOURCE_DIR} )
0015
0016 if(KDE_PLATFORM_FEATURE_BINARY_COMPATIBLE_FEATURE_REDUCTION)
0017     set(PLASMA_NO_PACKAGE_EXTRADATA TRUE)
0018 endif()
0019
0020 MACRO(PLASMA_UNIT_TESTS)
0021        FOREACH(_testname ${ARGN})
0022                set(libs Qt${QT_MAJOR_VERSION}::Qml Qt${QT_MAJOR_VERSION}::Test KF5::Plasma KF5::PlasmaQuick
0023                         KF5::Archive KF5::CoreAddons KF5::ConfigGui KF5::I18n
0024                         KF5::Service KF5::IconThemes
0025                         KF5::Declarative)
0026                if(QT_QTOPENGL_FOUND)
0027                    list(APPEND libs Qt${QT_MAJOR_VERSION}::OpenGL)
0028                endif()
0029                ecm_add_test(${_testname}.cpp
0030                             LINK_LIBRARIES ${libs}
0031                             NAME_PREFIX "plasma-")
0032                target_include_directories(${_testname} PRIVATE "$<BUILD_INTERFACE:$<TARGET_PROPERTY:KF5PlasmaQuick,INCLUDE_DIRECTORIES>>;")
0033        ENDFOREACH(_testname)
0034 ENDMACRO(PLASMA_UNIT_TESTS)
0035
0036 PLASMA_UNIT_TESTS(
0037     dialogqmltest
0038     dialogstatetest
0039     pluginloadertest
0040     framesvgtest
0041     iconitemtest
0042     themetest
0043 )
0044
0045 if(NOT EXCLUDE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT" AND
0046    EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS 5.83.0)
0047     PLASMA_UNIT_TESTS(configmodeltest)
0048 endif()
0049
0050 if(HAVE_X11)
0051     ecm_add_test(
0052         dialognativetest.cpp
0053         TEST_NAME dialognativetest
0054         LINK_LIBRARIES Qt${QT_MAJOR_VERSION}::Gui Qt${QT_MAJOR_VERSION}::Test Qt${QT_MAJOR_VERSION}::Qml Qt${QT_MAJOR_VERSION}::Quick KF5::WindowSystem KF5::Plasma KF5::PlasmaQuick
0055     )
0056     ecm_add_test(
0057         iconitemhidpitest.cpp
0058         TEST_NAME iconitemhidpitest
0059         LINK_LIBRARIES Qt::Gui Qt::Test Qt::Qml Qt::Quick KF5::IconThemes KF5::WindowSystem KF5::Plasma KF5::PlasmaQuick
0060     )
0061     set_tests_properties(iconitemhidpitest PROPERTIES ENVIRONMENT "QT_SCALE_FACTOR=1.25")
0062 endif()
0063
0064 ecm_add_test(
0065     coronatest.cpp
0066     coronatestresources.qrc
0067     TEST_NAME coronatest
0068     LINK_LIBRARIES Qt${QT_MAJOR_VERSION}::Gui Qt${QT_MAJOR_VERSION}::Widgets Qt${QT_MAJOR_VERSION}::Test KF5::Plasma KF5::CoreAddons KF5::XmlGui
0069 )
0070
0071 ecm_add_test(
0072     sortfiltermodeltest.cpp
0073     ../src/declarativeimports/core/datamodel.cpp
0074     ../src/declarativeimports/core/datasource.cpp
0075     TEST_NAME plasma-sortfiltermodeltest
0076     LINK_LIBRARIES KF5::Plasma Qt${QT_MAJOR_VERSION}::Gui Qt${QT_MAJOR_VERSION}::Test KF5::I18n KF5::Service Qt${QT_MAJOR_VERSION}::Qml
0077 )
0078
0079
0080 #Add a test that i18n is not used directly in any import.
0081 # It should /always/ be i18nd
0082 find_program(SH bash)
0083 if(SH)
0084     add_test(i18ndcheck ${SH} ${CMAKE_CURRENT_SOURCE_DIR}/i18ndcheck.sh ${CMAKE_SOURCE_DIR}/src/declarativeimports)
0085 endif()