libplasma/autotests/CMakeLists.txt

0001 find_package(Qt6Test ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0002 set_package_properties(Qt6Test PROPERTIES PURPOSE "Required for tests")
0003
0004 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_BINARY_DIR})
0005 remove_definitions(-DQT_NO_CAST_FROM_ASCII -DQT_STRICT_ITERATORS -DQT_NO_CAST_FROM_BYTEARRAY -DQT_NO_KEYWORDS)
0006
0007 include(ECMMarkAsTest)
0008 include(ECMAddTests)
0009
0010 find_package(KF6CoreAddons REQUIRED)
0011 find_package(Qt6Widgets REQUIRED)
0012
0013 # add_definitions( -DKDESRCDIR=${CMAKE_CURRENT_SOURCE_DIR} )
0014
0015 if(KDE_PLATFORM_FEATURE_BINARY_COMPATIBLE_FEATURE_REDUCTION)
0016     set(PLASMA_NO_PACKAGE_EXTRADATA TRUE)
0017 endif()
0018
0019 MACRO(PLASMA_UNIT_TESTS)
0020        FOREACH(_testname ${ARGN})
0021                set(libs Qt6::Qml Qt6::Test Plasma::Plasma Plasma::PlasmaQuick
0022                         KF6::Archive KF6::CoreAddons KF6::ConfigGui KF6::I18n KF6::IconThemes)
0023                if(QT_QTOPENGL_FOUND)
0024                    list(APPEND libs Qt6::OpenGL)
0025                endif()
0026                ecm_add_test(${_testname}.cpp
0027                             LINK_LIBRARIES ${libs}
0028                             NAME_PREFIX "plasma-")
0029                target_include_directories(${_testname} PRIVATE "$<BUILD_INTERFACE:$<TARGET_PROPERTY:PlasmaQuick,INCLUDE_DIRECTORIES>>;")
0030        ENDFOREACH(_testname)
0031 ENDMACRO(PLASMA_UNIT_TESTS)
0032
0033 PLASMA_UNIT_TESTS(
0034     dialogqmltest
0035     dialogstatetest
0036     pluginloadertest
0037     themetest
0038     sharedqmlenginetest
0039 )
0040
0041 kcoreaddons_add_plugin(dummycontainmentaction SOURCES dummycontainmentaction.cpp INSTALL_NAMESPACE "plasma/containmentactions" STATIC)
0042 target_link_libraries(dummycontainmentaction Plasma::Plasma)
0043 kcoreaddons_target_static_plugins(pluginloadertest NAMESPACE "plasma/containmentactions")
0044
0045 if(HAVE_X11)
0046     ecm_add_test(
0047         dialognativetest.cpp
0048         TEST_NAME dialognativetest
0049         LINK_LIBRARIES Qt6::Gui Qt6::Test Qt6::Qml Qt6::Quick KF6::WindowSystem Plasma::Plasma Plasma::PlasmaQuick
0050     )
0051 endif()
0052
0053 ecm_add_test(
0054     coronatest.cpp
0055     coronatestresources.qrc
0056     TEST_NAME coronatest
0057     LINK_LIBRARIES Qt6::Gui Qt6::Qml Qt6::Widgets Qt6::Test Plasma::Plasma KF6::CoreAddons
0058 )
0059
0060 ecm_add_test(
0061     quickviewsharedenginetest.cpp
0062     LINK_LIBRARIES Qt6::Test Plasma::PlasmaQuick
0063 )
0064
0065
0066 #Add a test that i18n is not used directly in any import.
0067 # It should /always/ be i18nd
0068 find_program(SH bash)
0069 if(SH)
0070     add_test(i18ndcheck ${SH} ${CMAKE_CURRENT_SOURCE_DIR}/i18ndcheck.sh ${CMAKE_SOURCE_DIR}/src/declarativeimports)
0071 endif()