libksysguard/processcore/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"processcore\")
0002
0003 ########### next target ###############
0004
0005 set(ksysguard_LIB_SRCS
0006    application_data_model.cpp
0007    cgroup.cpp
0008    cgroup_data_model.cpp
0009    extended_process_list.cpp
0010    processes.cpp
0011    process.cpp
0012    process_attribute.cpp
0013    processes_local_p.cpp
0014    processes_remote_p.cpp
0015    processes_base_p.cpp
0016    processes_atop_p.cpp
0017    process_controller.cpp
0018    process_attribute_model.cpp
0019    process_data_model.cpp
0020    process_data_provider.cpp
0021    read_procsmaps_runnable.cpp
0022 )
0023 ecm_qt_declare_logging_category(ksysguard_LIB_SRCS HEADER processcore_debug.h IDENTIFIER LIBKSYSGUARD_PROCESSCORE CATEGORY_NAME org.kde.libksysguard.processcore
0024     DESCRIPTION "libksysguard (processcore)" EXPORT LIBKSYSGUARD)
0025
0026 add_library(processcore ${ksysguard_LIB_SRCS})
0027 add_library(KSysGuard::ProcessCore ALIAS processcore)
0028
0029 target_link_libraries(processcore
0030    PUBLIC
0031     Qt::Core
0032     KSysGuard::Formatter
0033    PRIVATE
0034     KF5::I18n
0035     KF5::AuthCore
0036     KF5::CoreAddons
0037     KF5::Service
0038     ZLIB::ZLIB
0039 )
0040
0041 if( ${CMAKE_SYSTEM_NAME} MATCHES "NetBSD" )
0042   message(STATUS "Adding kvm library on NetBSD")
0043   target_link_libraries(processcore kvm)
0044 endif()
0045
0046 if(NOT HAVE_CLOCK_GETTIME_C)
0047     target_link_libraries(processcore PRIVATE rt)
0048 endif()
0049
0050 target_include_directories(processcore
0051     PUBLIC
0052         "$<BUILD_INTERFACE:${libksysguard_SOURCE_DIR}>"
0053         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/ksysguard>"
0054 )
0055 set_target_properties(processcore PROPERTIES
0056     VERSION ${KSYSGUARD_VERSION}
0057     SOVERSION ${KSYSGUARD_SOVERSION}
0058     EXPORT_NAME ProcessCore
0059 )
0060 install(TARGETS processcore EXPORT libksysguardLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0061
0062 add_subdirectory(declarative)
0063 add_subdirectory(plugins)
0064
0065 ########### install files ###############
0066
0067 install( FILES
0068     processes.h
0069     process.h
0070     process_controller.h
0071     process_attribute.h
0072     process_data_provider.h
0073     process_data_model.h
0074     process_attribute_model.h
0075     formatter.h
0076     unit.h
0077     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/ksysguard/processcore
0078     COMPONENT Devel
0079 )
0080
0081 #------ KAuth stuff
0082
0083 if(ENABLE_KAUTH_HELPER)
0084     # Auth example helper
0085     set(ksysguardprocesslist_helper_srcs
0086         helper.cpp
0087         process.cpp
0088         processes_local_p.cpp
0089         processes_base_p.cpp
0090         read_procsmaps_runnable.cpp
0091     )
0092
0093     add_executable(ksysguardprocesslist_helper ${ksysguardprocesslist_helper_srcs})
0094     target_link_libraries(ksysguardprocesslist_helper Qt::Core KF5::AuthCore KF5::I18n)
0095     install(TARGETS ksysguardprocesslist_helper DESTINATION ${KAUTH_HELPER_INSTALL_DIR})
0096
0097     kauth_install_helper_files(ksysguardprocesslist_helper org.kde.ksysguard.processlisthelper root)
0098     kauth_install_actions(org.kde.ksysguard.processlisthelper actions.actions)
0099
0100     set_target_properties(ksysguardprocesslist_helper PROPERTIES COMPILE_FLAGS "-Wall -ggdb")
0101 endif()