libksysguard/processcore/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"processcore\")
0002
0003 ########### next target ###############
0004
0005 set(ksysguard_LIB_SRCS
0006    application_data_model.cpp application_data_model.h
0007    cgroup.cpp cgroup.h
0008    cgroup_data_model.cpp cgroup_data_model.h
0009    extended_process_list.cpp extended_process_list.h
0010    processes.cpp
0011    process.cpp
0012    process_attribute.cpp
0013    processes_local_p.cpp processes_local_p.h
0014    processes_remote_p.cpp processes_remote_p.h
0015    processes_base_p.cpp processes_base_p.h
0016    processes_atop_p.cpp processes_atop_p.h atop_p.h
0017    process_controller.cpp
0018    process_attribute_model.cpp
0019    process_data_model.cpp
0020    process_data_provider.cpp
0021    read_procsmaps_runnable.cpp read_procsmaps_runnable.h
0022 )
0023 ecm_qt_declare_logging_category(ksysguard_LIB_SRCS HEADER processcore_debug.h IDENTIFIER LIBKSYSGUARD_PROCESSCORE CATEGORY_NAME org.kde.libksysguard.processcore
0024     DESCRIPTION "libksysguard (processcore)" EXPORT LIBKSYSGUARD)
0025
0026 add_library(processcore ${ksysguard_LIB_SRCS})
0027 add_library(KSysGuard::ProcessCore ALIAS processcore)
0028
0029 generate_export_header(processcore)
0030
0031 target_link_libraries(processcore
0032    PUBLIC
0033     Qt::Core
0034     KSysGuard::Formatter
0035    PRIVATE
0036     KF6::I18n
0037     KF6::AuthCore
0038     KF6::CoreAddons
0039     KF6::Service
0040     ZLIB::ZLIB
0041 )
0042
0043 if( ${CMAKE_SYSTEM_NAME} MATCHES "NetBSD" )
0044   message(STATUS "Adding kvm library on NetBSD")
0045   target_link_libraries(processcore kvm)
0046 endif()
0047
0048 if(NOT HAVE_CLOCK_GETTIME_C)
0049     target_link_libraries(processcore PRIVATE rt)
0050 endif()
0051
0052 target_include_directories(processcore
0053     PUBLIC
0054         "$<BUILD_INTERFACE:${libksysguard_SOURCE_DIR}>"
0055         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/ksysguard>"
0056 )
0057 set_target_properties(processcore PROPERTIES
0058     VERSION ${KSYSGUARD_VERSION}
0059     SOVERSION ${KSYSGUARD_SOVERSION}
0060     EXPORT_NAME ProcessCore
0061 )
0062 install(TARGETS processcore EXPORT libksysguardLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0063
0064 add_subdirectory(declarative)
0065 add_subdirectory(plugins)
0066
0067 ########### install files ###############
0068
0069 install( FILES
0070     processes.h
0071     process.h
0072     process_controller.h
0073     process_attribute.h
0074     process_data_provider.h
0075     process_data_model.h
0076     process_attribute_model.h
0077     formatter.h
0078     unit.h
0079     ${CMAKE_CURRENT_BINARY_DIR}/processcore_export.h
0080     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/ksysguard/processcore
0081     COMPONENT Devel
0082 )
0083
0084 #------ KAuth stuff
0085
0086 if(ENABLE_KAUTH_HELPER)
0087     # Auth example helper
0088     set(ksysguardprocesslist_helper_srcs
0089         helper.cpp helper.h
0090         process.cpp
0091         processes_local_p.cpp processes_local_p.h
0092         processes_base_p.cpp processes_base_p.h
0093         read_procsmaps_runnable.cpp read_procsmaps_runnable.h
0094     )
0095
0096     add_executable(ksysguardprocesslist_helper ${ksysguardprocesslist_helper_srcs})
0097     target_link_libraries(ksysguardprocesslist_helper Qt::Core KF6::AuthCore KF6::I18n)
0098     install(TARGETS ksysguardprocesslist_helper DESTINATION ${KAUTH_HELPER_INSTALL_DIR})
0099
0100     kauth_install_helper_files(ksysguardprocesslist_helper org.kde.ksysguard.processlisthelper root)
0101     kauth_install_actions(org.kde.ksysguard.processlisthelper actions.actions)
0102
0103     set_target_properties(ksysguardprocesslist_helper PROPERTIES COMPILE_FLAGS "-Wall -ggdb")
0104 endif()