src/libdpms/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: 2022 Aleix Pol Gonzalez <aleixpol@kde.org>
0003
0004 add_library(KF5ScreenDpms SHARED)
0005 target_sources(KF5ScreenDpms PRIVATE dpms.cpp abstractdpmshelper.cpp waylanddpmshelper.cpp xcbdpmshelper.cpp waylanddpmshelper.cpp)
0006 target_link_libraries(KF5ScreenDpms PUBLIC Qt::Gui
0007                                     PRIVATE XCB::XCB XCB::DPMS XCB::RANDR
0008                                             Qt::GuiPrivate Qt::WaylandClient Wayland::Client
0009 )
0010
0011 if (QT_MAJOR_VERSION EQUAL "5")
0012     target_link_libraries(KF5ScreenDpms PRIVATE Qt::X11Extras)
0013     ecm_add_qtwayland_client_protocol(KF5ScreenDpms
0014         PROTOCOL ${PLASMA_WAYLAND_PROTOCOLS_DIR}/dpms.xml
0015         BASENAME dpms
0016     )
0017 else()
0018     qt6_generate_wayland_protocol_client_sources(KF5ScreenDpms FILES ${PLASMA_WAYLAND_PROTOCOLS_DIR}/dpms.xml)
0019 endif()
0020
0021 set_target_properties(KF5ScreenDpms PROPERTIES
0022     VERSION "${KSCREEN_VERSION}"
0023     SOVERSION "${KSCREEN_SOVERSION}"
0024     EXPORT_NAME ScreenDpms
0025 )
0026 generate_export_header(KF5ScreenDpms BASE_NAME KScreenDpms)
0027
0028 install(TARGETS KF5ScreenDpms EXPORT KF5ScreenTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0029 add_library(KF5::ScreenDpms ALIAS KF5ScreenDpms)
0030
0031 ecm_qt_declare_logging_category(KF5ScreenDpms
0032                                 HEADER kscreendpms_debug.h
0033                                 IDENTIFIER KSCREEN_DPMS
0034                                 CATEGORY_NAME org.kde.kscreen.dpms
0035 )
0036
0037 ecm_generate_headers(KScreenDpms_HEADERS
0038     HEADER_NAMES
0039         Dpms
0040     PREFIX KScreenDpms
0041     REQUIRED_HEADERS KScreenDpms_REQ_HEADERS
0042 )
0043
0044 target_include_directories(KF5ScreenDpms INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KScreen>"
0045                                                    "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR}>"
0046 )
0047
0048 install(FILES ${KScreenDpms_HEADERS}
0049         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KScreen/KScreenDpms
0050         COMPONENT Devel)
0051 install(FILES ${KScreenDpms_REQ_HEADERS} ${CMAKE_CURRENT_BINARY_DIR}/kscreendpms_export.h
0052         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KScreen/kscreendpms)