src/libdpms/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: 2022 Aleix Pol Gonzalez <aleixpol@kde.org>
0003
0004 add_library(KF6ScreenDpms SHARED)
0005 target_sources(KF6ScreenDpms PRIVATE dpms.cpp abstractdpmshelper.cpp waylanddpmshelper.cpp xcbdpmshelper.cpp waylanddpmshelper.cpp)
0006 target_link_libraries(KF6ScreenDpms PUBLIC Qt::Gui
0007                                     PRIVATE XCB::XCB XCB::DPMS XCB::RANDR
0008                                             Qt::GuiPrivate Qt::WaylandClient Wayland::Client
0009 )
0010
0011 qt6_generate_wayland_protocol_client_sources(KF6ScreenDpms FILES ${PLASMA_WAYLAND_PROTOCOLS_DIR}/dpms.xml)
0012
0013 set_target_properties(KF6ScreenDpms PROPERTIES
0014     VERSION "${KSCREEN_VERSION}"
0015     SOVERSION "${KSCREEN_SOVERSION}"
0016     EXPORT_NAME ScreenDpms
0017 )
0018 generate_export_header(KF6ScreenDpms BASE_NAME KScreenDpms)
0019
0020 install(TARGETS KF6ScreenDpms EXPORT KF6ScreenTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0021 add_library(KF6::ScreenDpms ALIAS KF6ScreenDpms)
0022
0023 ecm_qt_declare_logging_category(KF6ScreenDpms
0024                                 HEADER kscreendpms_debug.h
0025                                 IDENTIFIER KSCREEN_DPMS
0026                                 CATEGORY_NAME org.kde.kscreen.dpms
0027 )
0028
0029 ecm_generate_headers(KScreenDpms_HEADERS
0030     HEADER_NAMES
0031         Dpms
0032     PREFIX KScreenDpms
0033     REQUIRED_HEADERS KScreenDpms_REQ_HEADERS
0034 )
0035
0036 target_include_directories(KF6ScreenDpms INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KScreen>"
0037                                                    "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR}>"
0038 )
0039
0040 install(FILES ${KScreenDpms_HEADERS}
0041         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KScreen/KScreenDpms
0042         COMPONENT Devel)
0043 install(FILES ${KScreenDpms_REQ_HEADERS} ${CMAKE_CURRENT_BINARY_DIR}/kscreendpms_export.h
0044         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KScreen/kscreendpms)