kwayland/src/CMakeLists.txt

0001 add_subdirectory(client)
0002
0003 # The server part of this repo has been moved to Plasma kwayland-server since 5.73
0004 if(EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS 5.74.0)
0005     add_subdirectory(server)
0006 endif()
0007
0008 add_subdirectory(tools)
0009
0010 ecm_qt_install_logging_categories(
0011     EXPORT KWAYLAND
0012     FILE kwayland.categories
0013     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0014 )
0015
0016
0017 if(BUILD_QCH)
0018     macro(_make_absolute var_name base_path)
0019         set(_result)
0020         foreach(_path ${${var_name}})
0021             if(IS_ABSOLUTE "${_path}")
0022                 list(APPEND _result "${_path}")
0023             else()
0024                 list(APPEND _result "${base_path}/${_path}")
0025             endif()
0026         endforeach()
0027         set(${var_name} ${_result})
0028     endmacro()
0029
0030     _make_absolute(KWaylandClient_APIDOX_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/client")
0031     _make_absolute(KWaylandServer_APIDOX_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/server")
0032
0033     ecm_add_qch(
0034         KF5Wayland_QCH
0035         NAME KWayland
0036         BASE_NAME KF5Wayland
0037         VERSION ${KF_VERSION}
0038         ORG_DOMAIN org.kde
0039         SOURCES # using only public headers, to cover only public API
0040             ${KWaylandClient_APIDOX_SRCS}
0041             ${KWaylandServer_APIDOX_SRCS}
0042         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0043         LINK_QCHS
0044             Qt5Gui_QCH
0045         INCLUDE_DIRS
0046             ${KWaylandClient_APIDOX_BUILD_INCLUDE_DIRS}
0047             ${KWaylandServer_APIDOX_BUILD_INCLUDE_DIRS}
0048         BLANK_MACROS
0049             KWAYLANDCLIENT_EXPORT
0050             KWAYLANDCLIENT_DEPRECATED
0051             KWAYLANDCLIENT_DEPRECATED_EXPORT
0052             "KWAYLANDCLIENT_DEPRECATED_VERSION(x, y, t)"
0053             "KWAYLANDCLIENT_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0054             "KWAYLANDCLIENT_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0055             "KWAYLANDCLIENT_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0056             KWAYLANDSERVER_EXPORT
0057             KWAYLANDSERVER_DEPRECATED
0058             KWAYLANDSERVER_DEPRECATED_EXPORT
0059             "KWAYLANDSERVER_DEPRECATED_VERSION(x, y, t)"
0060         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0061         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0062         COMPONENT Devel
0063     )
0064 endif()