kwayland/src/CMakeLists.txt

0001 add_subdirectory(client)
0002
0003 add_subdirectory(tools)
0004
0005 ecm_qt_install_logging_categories(
0006     EXPORT KWAYLAND
0007     FILE kwayland.categories
0008     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0009 )
0010
0011
0012 if(BUILD_QCH)
0013     macro(_make_absolute var_name base_path)
0014         set(_result)
0015         foreach(_path ${${var_name}})
0016             if(IS_ABSOLUTE "${_path}")
0017                 list(APPEND _result "${_path}")
0018             else()
0019                 list(APPEND _result "${base_path}/${_path}")
0020             endif()
0021         endforeach()
0022         set(${var_name} ${_result})
0023     endmacro()
0024
0025     _make_absolute(KWaylandClient_APIDOX_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/client")
0026
0027     ecm_add_qch(
0028         KWayland_QCH
0029         NAME KWayland
0030         BASE_NAME KWayland
0031         VERSION ${PROJECT_VERSION}
0032         ORG_DOMAIN org.kde
0033         SOURCES # using only public headers, to cover only public API
0034             ${KWaylandClient_APIDOX_SRCS}
0035         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0036         LINK_QCHS
0037             Qt6Gui_QCH
0038         INCLUDE_DIRS
0039             ${KWaylandClient_APIDOX_BUILD_INCLUDE_DIRS}
0040         BLANK_MACROS
0041             KWAYLANDCLIENT_EXPORT
0042             KWAYLANDCLIENT_DEPRECATED
0043             KWAYLANDCLIENT_DEPRECATED_EXPORT
0044             "KWAYLANDCLIENT_DEPRECATED_VERSION(x, y, t)"
0045             "KWAYLANDCLIENT_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0046             "KWAYLANDCLIENT_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0047             "KWAYLANDCLIENT_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0048         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0049         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0050         COMPONENT Devel
0051     )
0052 endif()