potd/plugins/CMakeLists.txt

0001 configure_file(config-NetworkManagerQt.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-NetworkManagerQt.h)
0002
0003 set(potd_engine_SRCS
0004         cachedprovider.cpp
0005         potdbackend.cpp
0006         potdengine.cpp
0007         potdprovidermodel.cpp
0008         potdplugin.cpp
0009 )
0010
0011 ecm_qt_declare_logging_category(potd_engine_SRCS
0012                                 HEADER debug.h
0013                                 IDENTIFIER WALLPAPERPOTD
0014                                 CATEGORY_NAME kde.wallpapers.potd
0015                                 DEFAULT_SEVERITY Info)
0016
0017 add_library(plasma_wallpaper_potdplugin SHARED ${potd_engine_SRCS})
0018 target_link_libraries(plasma_wallpaper_potdplugin plasmapotdprovidercore
0019     KF5::I18n
0020     KF5::KIOCore
0021     Qt::DBus
0022     Qt::Qml
0023     Qt::Widgets # QFileDialog
0024 )
0025 if (HAVE_NetworkManagerQt)
0026     target_link_libraries(plasma_wallpaper_potdplugin KF5::NetworkManagerQt)
0027 elseif(${QT_MAJOR_VERSION} GREATER_EQUAL 6)
0028     target_link_libraries(plasma_wallpaper_potdplugin Qt::Network)
0029 endif()
0030
0031 install(TARGETS plasma_wallpaper_potdplugin DESTINATION ${KDE_INSTALL_QMLDIR}/org/kde/plasma/wallpapers/potd)
0032 install(FILES qmldir DESTINATION ${KDE_INSTALL_QMLDIR}/org/kde/plasma/wallpapers/potd)
0033
0034 ########### plugin core library ############
0035 set(POTDPROVIDER_VERSION 1.0.0)
0036 set(POTDPROVIDER_VERSION_MAJOR 1)
0037
0038 set(potd_provider_core_SRCS
0039         potdprovider.cpp
0040         ${CMAKE_CURRENT_BINARY_DIR}/plasma_potd_export.h
0041 )
0042
0043 add_library(plasmapotdprovidercore SHARED ${potd_provider_core_SRCS})
0044 add_library(Plasma::PotdProvider ALIAS plasmapotdprovidercore)
0045 set_target_properties(plasmapotdprovidercore PROPERTIES
0046     VERSION ${POTDPROVIDER_VERSION}
0047     SOVERSION ${POTDPROVIDER_VERSION_MAJOR}
0048     EXPORT_NAME PotdProvider
0049 )
0050 target_link_libraries( plasmapotdprovidercore Qt::Gui KF5::CoreAddons KF5::ConfigCore KF5::KIOCore)
0051 target_include_directories(plasmapotdprovidercore
0052     PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
0053     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>"
0054 )
0055 generate_export_header(plasmapotdprovidercore BASE_NAME PLASMA_POTD EXPORT_FILE_NAME plasma_potd_export.h)
0056
0057 install(TARGETS plasmapotdprovidercore EXPORT plasmapotdproviderTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0058 install(FILES
0059         potdprovider.h
0060         ${CMAKE_CURRENT_BINARY_DIR}/plasma_potd_export.h
0061     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/plasma/potdprovider
0062     COMPONENT Devel
0063 )
0064
0065 write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/PlasmaPotdProviderConfigVersion.cmake
0066     VERSION "${POTDPROVIDER_VERSION}"
0067     COMPATIBILITY SameMajorVersion
0068 )
0069
0070 set(CMAKECONFIG_INSTALL_DIR ${KDE_INSTALL_CMAKEPACKAGEDIR}/PlasmaPotdProvider)
0071 configure_package_config_file(PlasmaPotdProvider.cmake.in
0072         "${CMAKE_CURRENT_BINARY_DIR}/PlasmaPotdProviderConfig.cmake"
0073     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0074 )
0075
0076 install(FILES
0077         ${CMAKE_CURRENT_BINARY_DIR}/PlasmaPotdProviderConfig.cmake
0078         ${CMAKE_CURRENT_BINARY_DIR}/PlasmaPotdProviderConfigVersion.cmake
0079     DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0080     COMPONENT Devel
0081 )
0082
0083 install(EXPORT plasmapotdproviderTargets
0084     NAMESPACE Plasma::
0085     DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0086     FILE PlasmaPotdProviderTargets.cmake
0087     COMPONENT Devel
0088 )
0089
0090 add_subdirectory(providers)