potd/plugins/CMakeLists.txt

0001 add_library(plasma_wallpaper_potdplugin_debug STATIC)
0002 set_property(TARGET plasma_wallpaper_potdplugin_debug PROPERTY POSITION_INDEPENDENT_CODE ON)
0003 target_link_libraries(plasma_wallpaper_potdplugin_debug
0004     Qt::Core
0005 )
0006 ecm_qt_declare_logging_category(plasma_wallpaper_potdplugin_debug
0007     HEADER debug.h
0008     IDENTIFIER WALLPAPERPOTD
0009     CATEGORY_NAME kde.wallpapers.potd
0010     DEFAULT_SEVERITY Info
0011     DESCRIPTION "Wallpaper plugins"
0012     EXPORT KDEPLASMAADDONS
0013 )
0014
0015 ecm_add_qml_module(plasma_wallpaper_potdplugin URI org.kde.plasma.wallpapers.potd)
0016 target_sources(plasma_wallpaper_potdplugin PRIVATE
0017     cachedprovider.cpp
0018     potdbackend.cpp
0019     potdengine.cpp
0020     potdprovidermodel.cpp
0021     potdplugin.cpp
0022 )
0023 target_link_libraries(plasma_wallpaper_potdplugin PRIVATE plasmapotdprovidercore
0024     KF6::I18n
0025     KF6::KIOCore
0026     Qt::DBus
0027     Qt::Network
0028     Qt::Qml
0029     Qt::Widgets # QFileDialog
0030     plasma_wallpaper_potdplugin_debug
0031 )
0032 ecm_finalize_qml_module(plasma_wallpaper_potdplugin)
0033
0034 ########### plugin core library ############
0035 set(POTDPROVIDER_VERSION 2.0.0)
0036 set(POTDPROVIDER_VERSION_MAJOR 2)
0037
0038 add_library(plasmapotdprovidercore SHARED potdprovider.cpp)
0039 add_library(Plasma::PotdProvider ALIAS plasmapotdprovidercore)
0040 set_target_properties(plasmapotdprovidercore PROPERTIES
0041     VERSION ${POTDPROVIDER_VERSION}
0042     SOVERSION ${POTDPROVIDER_VERSION_MAJOR}
0043     EXPORT_NAME PotdProvider
0044 )
0045 target_link_libraries( plasmapotdprovidercore Qt::Gui KF6::CoreAddons KF6::ConfigCore KF6::KIOCore)
0046 target_include_directories(plasmapotdprovidercore
0047     PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
0048     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>"
0049 )
0050 ecm_generate_export_header(plasmapotdprovidercore
0051     BASE_NAME PLASMA_POTD
0052     EXPORT_FILE_NAME plasma_potd_export.h
0053     VERSION ${POTDPROVIDER_VERSION}
0054     DEPRECATED_BASE_VERSION 0
0055 )
0056
0057 install(TARGETS plasmapotdprovidercore EXPORT plasmapotdproviderTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0058 install(FILES
0059         potdprovider.h
0060         ${CMAKE_CURRENT_BINARY_DIR}/plasma_potd_export.h
0061     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/plasma/potdprovider
0062     COMPONENT Devel
0063 )
0064
0065 write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/PlasmaPotdProviderConfigVersion.cmake
0066     VERSION "${POTDPROVIDER_VERSION}"
0067     COMPATIBILITY SameMajorVersion
0068 )
0069
0070 set(CMAKECONFIG_INSTALL_DIR ${KDE_INSTALL_CMAKEPACKAGEDIR}/PlasmaPotdProvider)
0071 configure_package_config_file(PlasmaPotdProvider.cmake.in
0072         "${CMAKE_CURRENT_BINARY_DIR}/PlasmaPotdProviderConfig.cmake"
0073     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0074 )
0075
0076 install(FILES
0077         ${CMAKE_CURRENT_BINARY_DIR}/PlasmaPotdProviderConfig.cmake
0078         ${CMAKE_CURRENT_BINARY_DIR}/PlasmaPotdProviderConfigVersion.cmake
0079     DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0080     COMPONENT Devel
0081 )
0082
0083 install(EXPORT plasmapotdproviderTargets
0084     NAMESPACE Plasma::
0085     DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0086     FILE PlasmaPotdProviderTargets.cmake
0087     COMPONENT Devel
0088 )
0089
0090 add_subdirectory(providers)