kdecoration/src/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kdecoration\")
0002
0003 add_subdirectory(private)
0004
0005 set(libkdecoration2_SRCS
0006     decoratedclient.cpp
0007     decoratedclient.h
0008     decorationbutton.cpp
0009     decorationbuttongroup.cpp
0010     decorationbuttongroup.h
0011     decorationbuttongroup_p.h
0012     decorationbutton.h
0013     decorationbutton_p.h
0014     decoration.cpp
0015     decorationdefines.h
0016     decoration.h
0017     decoration_p.h
0018     decorationsettings.cpp
0019     decorationsettings.h
0020     decorationshadow.cpp
0021     decorationshadow.h
0022     decorationshadow_p.h
0023     decorationthemeprovider.cpp
0024     decorationthemeprovider.h
0025
0026 )
0027
0028 add_library(kdecorations2 SHARED ${libkdecoration2_SRCS})
0029 ecm_generate_export_header(kdecorations2
0030                                                 VERSION ${PROJECT_VERSION}
0031                                                 EXPORT_FILE_NAME kdecoration2/kdecoration2_export.h
0032                                                 DEPRECATION_VERSIONS 5.21
0033                                                 EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0034 )
0035
0036 add_library(KDecoration2::KDecoration ALIAS kdecorations2)
0037
0038 target_link_libraries(kdecorations2
0039     PUBLIC
0040         Qt::Core
0041         Qt::Gui
0042     PRIVATE
0043         kdecorations2private
0044         KF5::I18n
0045         KF5::CoreAddons
0046 )
0047
0048 target_include_directories(kdecorations2 INTERFACE "$<INSTALL_INTERFACE:${KDECORATION2_INCLUDEDIR}>" )
0049
0050 set_target_properties(kdecorations2 PROPERTIES VERSION   ${KDECORATION2_VERSION}
0051                                                SOVERSION ${KDECORATION2_SOVERSION}
0052                                                EXPORT_NAME KDecoration
0053 )
0054
0055 ecm_generate_headers(KDecoration2_CamelCase_HEADERS
0056   HEADER_NAMES
0057     DecoratedClient
0058     Decoration
0059     DecorationButton
0060     DecorationButtonGroup
0061     DecorationSettings
0062     DecorationShadow
0063     DecorationThemeProvider
0064   PREFIX
0065     KDecoration2
0066   REQUIRED_HEADERS KDecoration2_HEADERS
0067 )
0068 install(FILES ${KDecoration2_CamelCase_HEADERS}
0069         DESTINATION ${KDECORATION2_INCLUDEDIR}/KDecoration2
0070         COMPONENT Devel)
0071
0072 install(TARGETS kdecorations2 EXPORT KDecoration2Targets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0073
0074 install(
0075     FILES
0076         ${CMAKE_CURRENT_BINARY_DIR}/kdecoration2/kdecoration2_export.h
0077         ${KDecoration2_HEADERS}
0078         decorationdefines.h
0079     DESTINATION
0080         ${KDECORATION2_INCLUDEDIR}/kdecoration2
0081     COMPONENT
0082         Devel
0083 )