kdecoration/src/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kdecoration\")
0002
0003 add_subdirectory(private)
0004
0005 set(libkdecoration2_SRCS
0006     decoratedclient.cpp
0007     decoratedclient.h
0008     decorationbutton.cpp
0009     decorationbuttongroup.cpp
0010     decorationbuttongroup.h
0011     decorationbuttongroup_p.h
0012     decorationbutton.h
0013     decorationbutton_p.h
0014     decoration.cpp
0015     decorationdefines.h
0016     decoration.h
0017     decoration_p.h
0018     decorationsettings.cpp
0019     decorationsettings.h
0020     decorationshadow.cpp
0021     decorationshadow.h
0022     decorationshadow_p.h
0023     decorationthemeprovider.cpp
0024     decorationthemeprovider.h
0025
0026 )
0027
0028 add_library(kdecorations2 SHARED ${libkdecoration2_SRCS})
0029 ecm_generate_export_header(kdecorations2
0030     VERSION ${PROJECT_VERSION}
0031     EXPORT_FILE_NAME kdecoration2/kdecoration2_export.h
0032     DEPRECATION_VERSIONS 5.21
0033     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0034 )
0035
0036 add_library(KDecoration2::KDecoration ALIAS kdecorations2)
0037
0038 target_link_libraries(kdecorations2
0039     PUBLIC
0040         Qt::Core
0041         Qt::Gui
0042     PRIVATE
0043         kdecorations2private
0044         KF6::I18n
0045 )
0046
0047 target_include_directories(kdecorations2 INTERFACE "$<INSTALL_INTERFACE:${KDECORATION2_INCLUDEDIR}>" )
0048
0049 set_target_properties(kdecorations2 PROPERTIES VERSION   ${KDECORATION2_VERSION}
0050                                                SOVERSION ${KDECORATION2_SOVERSION}
0051                                                EXPORT_NAME KDecoration
0052 )
0053
0054 ecm_generate_headers(KDecoration2_CamelCase_HEADERS
0055   HEADER_NAMES
0056     DecoratedClient
0057     Decoration
0058     DecorationButton
0059     DecorationButtonGroup
0060     DecorationSettings
0061     DecorationShadow
0062     DecorationThemeProvider
0063   PREFIX
0064     KDecoration2
0065   REQUIRED_HEADERS KDecoration2_HEADERS
0066 )
0067 install(FILES ${KDecoration2_CamelCase_HEADERS}
0068         DESTINATION ${KDECORATION2_INCLUDEDIR}/KDecoration2
0069         COMPONENT Devel)
0070
0071 install(TARGETS kdecorations2 EXPORT KDecoration2Targets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0072
0073 install(
0074     FILES
0075         ${CMAKE_CURRENT_BINARY_DIR}/kdecoration2/kdecoration2_export.h
0076         ${KDecoration2_HEADERS}
0077         decorationdefines.h
0078     DESTINATION
0079         ${KDECORATION2_INCLUDEDIR}/kdecoration2
0080     COMPONENT
0081         Devel
0082 )