discover/discover/CMakeLists.txt

0001 add_subdirectory(icons)
0002 if(BUILD_TESTING)
0003     add_subdirectory(autotests)
0004 endif()
0005
0006 include_directories(${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR}/..)
0007
0008 ecm_qt_declare_logging_category(plasma_discover_SRCS HEADER discover_debug.h IDENTIFIER DISCOVER_LOG CATEGORY_NAME org.kde.plasma.discover DESCRIPTION "discover" EXPORT DISCOVER)
0009 kconfig_add_kcfg_files(plasma_discover_SRCS discoversettings.kcfgc GENERATE_MOC)
0010
0011 if (TARGET KUserFeedbackCore)
0012     kconfig_add_kcfg_files(plasma_discover_SRCS plasmauserfeedback.kcfgc GENERATE_MOC)
0013 endif()
0014
0015 add_executable(plasma-discover ${plasma_discover_SRCS}
0016     main.cpp
0017     DiscoverObject.cpp
0018     DiscoverDeclarativePlugin.cpp
0019
0020     AbstractAppsModel.cpp
0021     OdrsAppsModel.cpp
0022     FeaturedModel.cpp
0023     PaginateModel.cpp
0024     UnityLauncher.cpp
0025     ReadFile.cpp
0026     PowerManagementInterface.cpp
0027
0028     DiscoverObject.h
0029     DiscoverDeclarativePlugin.h
0030
0031     FeaturedModel.h
0032     PaginateModel.h
0033     UnityLauncher.h
0034     ReadFile.h
0035
0036
0037     resources.qrc
0038 )
0039 add_executable(Plasma::Discover ALIAS plasma-discover)
0040 set_target_properties(plasma-discover PROPERTIES INSTALL_RPATH ${CMAKE_INSTALL_FULL_LIBDIR}/plasma-discover)
0041
0042 target_link_libraries(plasma-discover PUBLIC
0043                                      KF5::Crash
0044                                      KF5::DBusAddons
0045                                      KF5::I18n
0046                                      KF5::ConfigGui
0047                                      KF5::KIOCore
0048                                      KF5::WindowSystem
0049                                      KF5::Notifications
0050                                      KF5::JobWidgets
0051                                      Qt::Widgets
0052                                      Qt::Quick
0053                                      Discover::Common
0054 )
0055
0056 if (TARGET Qt::WebView)
0057     target_link_libraries(plasma-discover PUBLIC Qt::WebView)
0058     target_compile_definitions(plasma-discover PUBLIC -DWITH_QTWEBVIEW=1)
0059 else()
0060     target_compile_definitions(plasma-discover PUBLIC -DWITH_QTWEBVIEW=0)
0061 endif()
0062
0063 if (TARGET KUserFeedbackCore)
0064     target_link_libraries(plasma-discover PRIVATE KUserFeedbackCore)
0065     target_compile_definitions(plasma-discover PRIVATE WITH_FEEDBACK=1)
0066 endif()
0067
0068 install(TARGETS plasma-discover ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0069
0070 # if (BUILD_DummyBackend)
0071 #     target_compile_definitions(plasma-discover PRIVATE $<$<CONFIG:Debug>:QT_QML_DEBUG=1>)
0072 # endif()
0073
0074 # Standard desktop file accepts local files as input.
0075 set(DesktopNoDisplay "false")
0076 find_program(DPKG dpkg)
0077 find_program(RPM rpm)
0078 set(DesktopMimeType "")
0079 if(DPKG)
0080      set(DesktopMimeType "${DesktopMimeType}application/vnd.debian.binary-package;")
0081 endif()
0082 if(RPM)
0083      set(DesktopMimeType "${DesktopMimeType}application/x-rpm;")
0084 endif()
0085 if(Flatpak_FOUND)
0086   set(DesktopMimeType "${DesktopMimeType}application/vnd.flatpak;application/vnd.flatpak.repo;application/vnd.flatpak.ref;")
0087 endif()
0088 set(DesktopExec "plasma-discover %F")
0089 configure_file(org.kde.discover.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.desktop)
0090 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0091
0092 # Support appstream:// URI
0093 set(DesktopNoDisplay "true")
0094 set(DesktopMimeType "x-scheme-handler/appstream;")
0095 set(DesktopExec "plasma-discover %U")
0096 configure_file(org.kde.discover.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.urlhandler.desktop)
0097 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.urlhandler.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0098
0099 # support snap:/ URI
0100 set(DesktopNoDisplay "true")
0101 set(DesktopMimeType "x-scheme-handler/snap;")
0102 set(DesktopExec "plasma-discover %U")
0103 configure_file(org.kde.discover.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.snap.desktop)
0104 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.snap.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0105
0106 if(EXISTS "/etc/debian_version")
0107     set(DesktopNoDisplay "true")
0108     set(DesktopMimeType "x-scheme-handler/apt")
0109     set(DesktopExec "plasma-discover %U")
0110     configure_file(org.kde.discover.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.apt.urlhandler.desktop)
0111     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.apt.urlhandler.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0112 endif()
0113
0114 install(FILES plasmadiscoverui.rc DESTINATION ${KDE_INSTALL_KXMLGUIDIR}/plasmadiscover)
0115 install(FILES org.kde.discover.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )