discover/discover/CMakeLists.txt

0001 add_subdirectory(icons)
0002 if(BUILD_TESTING)
0003     add_subdirectory(autotests)
0004 endif()
0005
0006 include_directories(${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR}/..)
0007
0008 ecm_qt_declare_logging_category(plasma_discover_SRCS HEADER discover_debug.h IDENTIFIER DISCOVER_LOG CATEGORY_NAME org.kde.plasma.discover DESCRIPTION "discover" EXPORT DISCOVER)
0009 kconfig_add_kcfg_files(plasma_discover_SRCS discoversettings.kcfgc GENERATE_MOC)
0010
0011 if (TARGET KF6::UserFeedbackCore)
0012     kconfig_add_kcfg_files(plasma_discover_SRCS plasmauserfeedback.kcfgc GENERATE_MOC)
0013 endif()
0014
0015 add_executable(plasma-discover ${plasma_discover_SRCS}
0016     main.cpp
0017     DiscoverObject.cpp
0018     DiscoverDeclarativePlugin.cpp
0019
0020     AbstractAppsModel.cpp
0021     OdrsAppsModel.cpp
0022     FeaturedModel.cpp
0023     PaginateModel.cpp
0024     UnityLauncher.cpp
0025     ReadFile.cpp
0026     PowerManagementInterface.cpp
0027
0028     DiscoverObject.h
0029     DiscoverDeclarativePlugin.h
0030
0031     FeaturedModel.h
0032     PaginateModel.h
0033     UnityLauncher.h
0034     ReadFile.h
0035
0036
0037     resources.qrc
0038 )
0039 add_executable(Plasma::Discover ALIAS plasma-discover)
0040 set_target_properties(plasma-discover PROPERTIES INSTALL_RPATH ${CMAKE_INSTALL_FULL_LIBDIR}/plasma-discover)
0041
0042 target_link_libraries(plasma-discover PUBLIC
0043                                      KF6::Crash
0044                                      KF6::DBusAddons
0045                                      KF6::I18n
0046                                      KF6::ConfigGui
0047                                      KF6::KIOCore
0048                                      KF6::WindowSystem
0049                                      KF6::Notifications
0050                                      KF6::JobWidgets
0051                                      KF6::StatusNotifierItem
0052                                      Qt::Widgets
0053                                      Qt::Quick
0054                                      Discover::Common
0055 )
0056
0057 if (TARGET Qt::WebView)
0058     target_link_libraries(plasma-discover PUBLIC Qt::WebView)
0059     target_compile_definitions(plasma-discover PUBLIC -DWITH_QTWEBVIEW=1)
0060 else()
0061     target_compile_definitions(plasma-discover PUBLIC -DWITH_QTWEBVIEW=0)
0062 endif()
0063
0064 if (TARGET KF6::UserFeedbackCore)
0065     target_link_libraries(plasma-discover PRIVATE KF6::UserFeedbackCore)
0066     target_compile_definitions(plasma-discover PRIVATE WITH_FEEDBACK=1)
0067 endif()
0068
0069 install(TARGETS plasma-discover ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0070
0071 # if (BUILD_DummyBackend)
0072 #     target_compile_definitions(plasma-discover PRIVATE $<$<CONFIG:Debug>:QT_QML_DEBUG=1>)
0073 # endif()
0074
0075 # Standard desktop file accepts local files as input.
0076 set(DesktopNoDisplay "false")
0077 find_program(DPKG dpkg)
0078 find_program(RPM rpm)
0079 set(DesktopMimeType "")
0080 if(DPKG)
0081      set(DesktopMimeType "${DesktopMimeType}application/vnd.debian.binary-package;")
0082 endif()
0083 if(RPM)
0084      set(DesktopMimeType "${DesktopMimeType}application/x-rpm;")
0085 endif()
0086 if(Flatpak_FOUND)
0087   set(DesktopMimeType "${DesktopMimeType}application/vnd.flatpak;application/vnd.flatpak.repo;application/vnd.flatpak.ref;")
0088 endif()
0089 set(DesktopExec "plasma-discover %F")
0090 configure_file(org.kde.discover.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.desktop)
0091 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0092
0093 # Support appstream:// URI
0094 set(DesktopNoDisplay "true")
0095 set(DesktopMimeType "x-scheme-handler/appstream;")
0096 set(DesktopExec "plasma-discover %U")
0097 configure_file(org.kde.discover.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.urlhandler.desktop)
0098 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.urlhandler.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0099
0100 # support snap:/ URI
0101 set(DesktopNoDisplay "true")
0102 set(DesktopMimeType "x-scheme-handler/snap;")
0103 set(DesktopExec "plasma-discover %U")
0104 configure_file(org.kde.discover.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.snap.desktop)
0105 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.snap.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0106
0107 if(EXISTS "/etc/debian_version")
0108     set(DesktopNoDisplay "true")
0109     set(DesktopMimeType "x-scheme-handler/apt")
0110     set(DesktopExec "plasma-discover %U")
0111     configure_file(org.kde.discover.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.apt.urlhandler.desktop)
0112     install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.discover.apt.urlhandler.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0113 endif()
0114
0115 install(FILES plasmadiscoverui.rc DESTINATION ${KDE_INSTALL_KXMLGUIDIR}/plasmadiscover)
0116 install(FILES org.kde.discover.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )