breeze/kstyle/CMakeLists.txt

0001 ################# Qt/KDE #################
0002 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED CONFIG COMPONENTS Widgets DBus)
0003 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0004     CoreAddons
0005     I18n
0006     Config
0007     GuiAddons
0008     IconThemes
0009     ConfigWidgets
0010     WindowSystem)
0011
0012 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} OPTIONAL_COMPONENTS Quick)
0013 set(BREEZE_HAVE_QTQUICK ${Qt${QT_MAJOR_VERSION}Quick_FOUND})
0014 if( BREEZE_HAVE_QTQUICK )
0015     find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS Kirigami2)
0016 endif()
0017
0018 if (TARGET Qt5::Core)
0019     find_package(Qt5 ${QT_MIN_VERSION} OPTIONAL_COMPONENTS X11Extras)
0020     set(BREEZE_HAVE_QTX11EXTRAS ${Qt5X11Extras_FOUND})
0021 elseif(NOT WIN32)
0022     set(BREEZE_HAVE_QTX11EXTRAS TRUE) # part of Qt6::Gui
0023 endif()
0024
0025 find_package( KF5FrameworkIntegration ${KF5_MIN_VERSION} CONFIG )
0026 set_package_properties(KF5FrameworkIntegration PROPERTIES
0027     DESCRIPTION "KF5 Framework Integration"
0028     URL "https://projects.kde.org/projects/frameworks/frameworkintegration"
0029     TYPE OPTIONAL
0030     PURPOSE "Required to use KStyle convenience functionalities in style")
0031
0032 set(BREEZE_HAVE_KSTYLE ${KF5FrameworkIntegration_FOUND})
0033
0034
0035 ################# includes #################
0036 include_directories(
0037   animations
0038   debug
0039 )
0040
0041 include_directories(${CMAKE_SOURCE_DIR}/libbreezecommon)
0042 include_directories(${CMAKE_BINARY_DIR}/libbreezecommon)
0043
0044 ################# configuration #################
0045 configure_file(config-breeze.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-breeze.h )
0046
0047 ########### next target ###############
0048 set(breeze_PART_SRCS
0049     animations/breezeanimation.cpp
0050     animations/breezeanimations.cpp
0051     animations/breezeanimationdata.cpp
0052     animations/breezebaseengine.cpp
0053     animations/breezebusyindicatordata.cpp
0054     animations/breezebusyindicatorengine.cpp
0055     animations/breezedialdata.cpp
0056     animations/breezedialengine.cpp
0057     animations/breezeenabledata.cpp
0058     animations/breezegenericdata.cpp
0059     animations/breezeheaderviewdata.cpp
0060     animations/breezeheaderviewengine.cpp
0061     animations/breezescrollbardata.cpp
0062     animations/breezescrollbarengine.cpp
0063     animations/breezespinboxengine.cpp
0064     animations/breezespinboxdata.cpp
0065     animations/breezestackedwidgetdata.cpp
0066     animations/breezestackedwidgetengine.cpp
0067     animations/breezetabbarengine.cpp
0068     animations/breezetabbardata.cpp
0069     animations/breezetoolboxengine.cpp
0070     animations/breezetransitiondata.cpp
0071     animations/breezetransitionwidget.cpp
0072     animations/breezewidgetstateengine.cpp
0073     animations/breezewidgetstatedata.cpp
0074     debug/breezewidgetexplorer.cpp
0075     breezeaddeventfilter.cpp
0076     breezeblurhelper.cpp
0077     breezeframeshadow.cpp
0078     breezehelper.cpp
0079     breezemdiwindowshadow.cpp
0080     breezemnemonics.cpp
0081     breezepropertynames.cpp
0082     breezeshadowhelper.cpp
0083     breezesplitterproxy.cpp
0084     breezestyle.cpp
0085     breezestyleplugin.cpp
0086     breezetileset.cpp
0087     breezewindowmanager.cpp
0088     breezetoolsareamanager.cpp
0089 )
0090
0091 kconfig_add_kcfg_files(breeze_PART_SRCS ../kdecoration/breezesettings.kcfgc)
0092 kconfig_add_kcfg_files(breeze_PART_SRCS breezestyleconfigdata.kcfgc)
0093 add_library(breeze MODULE ${breeze_PART_SRCS})
0094 target_link_libraries(breeze Qt::Core Qt::Gui Qt::Widgets Qt::DBus)
0095 if( BREEZE_HAVE_QTQUICK )
0096     target_link_libraries(breeze Qt::Quick KF5::CoreAddons KF5::Kirigami2)
0097 endif()
0098 if (TARGET Qt5::X11Extras)
0099     target_link_libraries(breeze Qt5::X11Extras)
0100 elseif (TARGET Qt6::Gui)
0101     target_link_libraries(breeze Qt6::GuiPrivate)
0102 endif()
0103 target_link_libraries(breeze KF5::CoreAddons KF5::ConfigCore KF5::ConfigWidgets KF5::GuiAddons KF5::IconThemes KF5::WindowSystem)
0104 target_link_libraries(breeze breezecommon5)
0105
0106 if(KF5FrameworkIntegration_FOUND)
0107     target_link_libraries(breeze KF5::Style)
0108 endif()
0109
0110 if (WIN32)
0111     # As stated in https://docs.microsoft.com/en-us/cpp/c-runtime-library/math-constants M_PI only gets defined
0112     # when if _USE_MATH_DEFINES is defined
0113     target_compile_definitions(breeze PRIVATE _USE_MATH_DEFINES _BSD_SOURCE)
0114 endif()
0115
0116
0117 ########### install files ###############
0118 install(TARGETS breeze DESTINATION ${KDE_INSTALL_QTPLUGINDIR}/styles/)
0119 install(FILES breeze.themerc  DESTINATION  ${KDE_INSTALL_DATADIR}/kstyle/themes)
0120
0121 ########### subdirectories ###############
0122 add_subdirectory(config)