breeze/kstyle/CMakeLists.txt

0001 ################# includes #################
0002 include_directories(
0003   animations
0004   debug
0005 )
0006
0007 include_directories(${CMAKE_SOURCE_DIR}/libbreezecommon)
0008 include_directories(${CMAKE_BINARY_DIR}/libbreezecommon)
0009
0010 ################# configuration #################
0011 configure_file(config-breeze.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-breeze.h )
0012
0013 ########### next target ###############
0014 set(breeze_PART_SRCS
0015     animations/breezeanimation.cpp
0016     animations/breezeanimations.cpp
0017     animations/breezeanimationdata.cpp
0018     animations/breezebaseengine.cpp
0019     animations/breezebusyindicatordata.cpp
0020     animations/breezebusyindicatorengine.cpp
0021     animations/breezedialdata.cpp
0022     animations/breezedialengine.cpp
0023     animations/breezeenabledata.cpp
0024     animations/breezegenericdata.cpp
0025     animations/breezeheaderviewdata.cpp
0026     animations/breezeheaderviewengine.cpp
0027     animations/breezescrollbardata.cpp
0028     animations/breezescrollbarengine.cpp
0029     animations/breezespinboxengine.cpp
0030     animations/breezespinboxdata.cpp
0031     animations/breezestackedwidgetdata.cpp
0032     animations/breezestackedwidgetengine.cpp
0033     animations/breezetabbarengine.cpp
0034     animations/breezetabbardata.cpp
0035     animations/breezetoolboxengine.cpp
0036     animations/breezetransitiondata.cpp
0037     animations/breezetransitionwidget.cpp
0038     animations/breezewidgetstateengine.cpp
0039     animations/breezewidgetstatedata.cpp
0040     debug/breezewidgetexplorer.cpp
0041     breezeaddeventfilter.cpp
0042     breezeblurhelper.cpp
0043     breezeframeshadow.cpp
0044     breezehelper.cpp
0045     breezemdiwindowshadow.cpp
0046     breezemnemonics.cpp
0047     breezepropertynames.cpp
0048     breezeshadowhelper.cpp
0049     breezesplitterproxy.cpp
0050     breezestyle.cpp
0051     breezestyleplugin.cpp
0052     breezetileset.cpp
0053     breezewindowmanager.cpp
0054     breezetoolsareamanager.cpp
0055 )
0056
0057 kconfig_add_kcfg_files(breeze_PART_SRCS ../kdecoration/breezesettings.kcfgc)
0058 kconfig_add_kcfg_files(breeze_PART_SRCS breezestyleconfigdata.kcfgc)
0059
0060
0061 add_library(breeze${QT_MAJOR_VERSION} MODULE ${breeze_PART_SRCS})
0062
0063 target_link_libraries(breeze${QT_MAJOR_VERSION}
0064     Qt${QT_MAJOR_VERSION}::Core
0065     Qt${QT_MAJOR_VERSION}::Gui
0066     Qt${QT_MAJOR_VERSION}::Widgets
0067     Qt${QT_MAJOR_VERSION}::DBus
0068 )
0069
0070 if( BREEZE_HAVE_QTQUICK )
0071     target_link_libraries(breeze${QT_MAJOR_VERSION}
0072         Qt${QT_MAJOR_VERSION}::Quick
0073         KF${QT_MAJOR_VERSION}::CoreAddons
0074     )
0075 endif()
0076
0077 target_link_libraries(breeze${QT_MAJOR_VERSION}
0078     KF${QT_MAJOR_VERSION}::CoreAddons
0079     KF${QT_MAJOR_VERSION}::ConfigCore
0080     KF${QT_MAJOR_VERSION}::ConfigGui
0081     KF${QT_MAJOR_VERSION}::GuiAddons
0082     KF${QT_MAJOR_VERSION}::IconThemes
0083     KF${QT_MAJOR_VERSION}::WindowSystem
0084 )
0085
0086 if(QT_MAJOR_VERSION STREQUAL "5")
0087     target_link_libraries(breeze5 KF5::ConfigWidgets)
0088     if (BREEZE_HAVE_QTQUICK)
0089         target_link_libraries(breeze5 KF5::Kirigami2)
0090     endif()
0091 else()
0092     target_link_libraries(breeze6 KF6::ColorScheme)
0093     if (BREEZE_HAVE_QTQUICK)
0094         target_link_libraries(breeze6 KF6::KirigamiPlatform)
0095     endif()
0096 endif()
0097
0098 target_link_libraries(breeze${QT_MAJOR_VERSION} breezecommon${QT_MAJOR_VERSION})
0099
0100 if(KF${QT_MAJOR_VERSION}FrameworkIntegration_FOUND)
0101     target_link_libraries(breeze${QT_MAJOR_VERSION}  KF${QT_MAJOR_VERSION}::Style)
0102 endif()
0103
0104
0105 if (WIN32)
0106     # As stated in https://docs.microsoft.com/en-us/cpp/c-runtime-library/math-constants M_PI only gets defined
0107     # when if _USE_MATH_DEFINES is defined
0108     target_compile_definitions(breeze${QT_MAJOR_VERSION}  PRIVATE _USE_MATH_DEFINES _BSD_SOURCE)
0109 endif()
0110
0111
0112 ########### install files ###############
0113 install(TARGETS breeze${QT_MAJOR_VERSION}  DESTINATION ${KDE_INSTALL_QTPLUGINDIR}/styles/)
0114 install(FILES breeze.themerc  DESTINATION  ${KDE_INSTALL_DATADIR}/kstyle/themes)
0115
0116 ########### subdirectories ###############
0117
0118 if (QT_MAJOR_VERSION EQUAL "6" AND TARGET "KF6::KCMUtils")
0119     add_subdirectory(config)
0120 endif()