pim/libkgapi/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002 set(PIM_VERSION "6.0.0")
0003
0004 set(KGAPI_LIB_VERSION ${PIM_VERSION})
0005
0006 project(kgapi VERSION ${KGAPI_LIB_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.246.0")
0010 set(QT_REQUIRED_VERSION "6.6.0")
0011 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017
0018 include(GenerateExportHeader)
0019 include(ECMGenerateHeaders)
0020 include(ECMQtDeclareLoggingCategory)
0021 include(ECMDeprecationSettings)
0022
0023 include(ECMPoQmTools)
0024 include(ECMSetupVersion)
0025 include(FeatureSummary)
0026 include(KDEGitCommitHooks)
0027 include(KDEClangFormat)
0028 include(ECMAddQch)
0029 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0030 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0031 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0032 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0033 option(BUILD_SASL_PLUGIN "Build the SASL plugin (only disable this for co-installability)" ON)
0034
0035
0036 set(CMAKE_AUTOMOC_MACRO_NAMES "Q_OBJECT" "Q_GADGET" "Q_NAMESPACE" "Q_NAMESPACE_EXPORT")
0037
0038
0039 ############## Find Packages ##############
0040 find_package(Qt6 ${QT_REQUIRED_VERSION} REQUIRED COMPONENTS
0041     Core
0042     Network
0043     Widgets
0044     Xml
0045 )
0046
0047 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0048     Wallet
0049 )
0050
0051 find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KF6Contacts ${KF_MIN_VERSION} CONFIG REQUIRED)
0053
0054 if(BUILD_SASL_PLUGIN)
0055     find_package(Sasl2)
0056     set_package_properties(Sasl2 PROPERTIES TYPE REQUIRED)
0057 endif()
0058
0059 ecm_setup_version(PROJECT
0060     VARIABLE_PREFIX KGAPI
0061     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kgapi_version.h"
0062     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6GAPIConfigVersion.cmake"
0063     SOVERSION 6
0064 )
0065
0066
0067 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0068 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.248.0)
0069
0070
0071 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0072
0073 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0074 if (USE_UNITY_CMAKE_SUPPORT)
0075     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0076 endif()
0077
0078
0079 ############## Targets ##############
0080 add_subdirectory(src)
0081 if (KGAPI_BUILD_EXAMPLES)
0082     add_subdirectory(examples)
0083 endif()
0084 if (BUILD_TESTING)
0085     add_subdirectory(autotests)
0086 endif()
0087
0088 ############## CMake Config Files ##############
0089 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6GAPI")
0090 set(KGAPI_KF6_COMPAT FALSE)
0091
0092 if (BUILD_QCH)
0093     ecm_install_qch_export(
0094         TARGETS KPim6GAPIBlogger_QCH KPim6GAPICalendar_QCH
0095         KPim6GAPICore_QCH KPim6GAPIDrive_QCH
0096         KPim6GAPILatitude_QCH KPim6GAPIPeople_QCH
0097         KPim6GAPIMaps_QCH KPim6GAPITasks_QCH
0098         FILE KPim6GAPIQchTargets.cmake
0099         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0100         COMPONENT Devel
0101     )
0102     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6GAPIQchTargets.cmake\")")
0103 endif()
0104
0105 configure_package_config_file(
0106     "${CMAKE_CURRENT_SOURCE_DIR}/KPimGAPIConfig.cmake.in"
0107     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GAPIConfig.cmake"
0108     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0109 )
0110
0111 install(FILES
0112     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GAPIConfig.cmake"
0113     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GAPIConfigVersion.cmake"
0114     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0115     COMPONENT Devel
0116 )
0117
0118 install(EXPORT KPim6GAPITargets
0119     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0120     FILE KPim6GAPITargets.cmake
0121     NAMESPACE KPim6::
0122 )
0123
0124 install(FILES
0125     "${CMAKE_CURRENT_BINARY_DIR}/kgapi_version.h"
0126     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI"
0127     COMPONENT Devel
0128 )
0129
0130
0131
0132 ecm_qt_install_logging_categories(
0133         EXPORT LIBKGAPI
0134         FILE libkgapi.categories
0135         DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0136         )
0137
0138
0139 ecm_install_po_files_as_qm(poqm)
0140
0141 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)