pim/libkgapi/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002 set(PIM_VERSION "6.0.40")
0003
0004 set(KGAPI_LIB_VERSION ${PIM_VERSION})
0005
0006 project(kgapi VERSION ${KGAPI_LIB_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.248.0")
0010 set(QT_REQUIRED_VERSION "6.6.0")
0011 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017
0018 include(GenerateExportHeader)
0019 include(ECMGenerateHeaders)
0020 include(ECMQtDeclareLoggingCategory)
0021 include(ECMDeprecationSettings)
0022 include(ECMFeatureSummary)
0023
0024 include(ECMPoQmTools)
0025 include(ECMSetupVersion)
0026 include(FeatureSummary)
0027 include(KDEGitCommitHooks)
0028 include(KDEClangFormat)
0029 include(ECMAddQch)
0030 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0031 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0032 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0033 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0034 option(BUILD_SASL_PLUGIN "Build the SASL plugin (only disable this for co-installability)" ON)
0035
0036
0037 set(CMAKE_AUTOMOC_MACRO_NAMES "Q_OBJECT" "Q_GADGET" "Q_NAMESPACE" "Q_NAMESPACE_EXPORT")
0038
0039
0040 ############## Find Packages ##############
0041 find_package(Qt6 ${QT_REQUIRED_VERSION} REQUIRED COMPONENTS
0042     Core
0043     Network
0044     Widgets
0045     Xml
0046 )
0047
0048 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0049     Wallet
0050 )
0051
0052 find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
0053 find_package(KF6Contacts ${KF_MIN_VERSION} CONFIG REQUIRED)
0054
0055 if(BUILD_SASL_PLUGIN)
0056     find_package(Sasl2)
0057     set_package_properties(Sasl2 PROPERTIES TYPE REQUIRED)
0058 endif()
0059
0060 ecm_setup_version(PROJECT
0061     VARIABLE_PREFIX KGAPI
0062     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kgapi_version.h"
0063     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6GAPIConfigVersion.cmake"
0064     SOVERSION 6
0065 )
0066
0067
0068 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0069 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.249.0)
0070
0071
0072 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0073
0074 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0075 if (USE_UNITY_CMAKE_SUPPORT)
0076     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0077 endif()
0078
0079
0080 ############## Targets ##############
0081 add_subdirectory(src)
0082 if (KGAPI_BUILD_EXAMPLES)
0083     add_subdirectory(examples)
0084 endif()
0085 if (BUILD_TESTING)
0086     add_subdirectory(autotests)
0087 endif()
0088
0089 ############## CMake Config Files ##############
0090 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6GAPI")
0091 set(KGAPI_KF6_COMPAT FALSE)
0092
0093 if (BUILD_QCH)
0094     ecm_install_qch_export(
0095         TARGETS KPim6GAPIBlogger_QCH KPim6GAPICalendar_QCH
0096         KPim6GAPICore_QCH KPim6GAPIDrive_QCH
0097         KPim6GAPILatitude_QCH KPim6GAPIPeople_QCH
0098         KPim6GAPIMaps_QCH KPim6GAPITasks_QCH
0099         FILE KPim6GAPIQchTargets.cmake
0100         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0101         COMPONENT Devel
0102     )
0103     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6GAPIQchTargets.cmake\")")
0104 endif()
0105
0106 configure_package_config_file(
0107     "${CMAKE_CURRENT_SOURCE_DIR}/KPimGAPIConfig.cmake.in"
0108     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GAPIConfig.cmake"
0109     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0110 )
0111
0112 install(FILES
0113     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GAPIConfig.cmake"
0114     "${CMAKE_CURRENT_BINARY_DIR}/KPim6GAPIConfigVersion.cmake"
0115     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0116     COMPONENT Devel
0117 )
0118
0119 install(EXPORT KPim6GAPITargets
0120     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0121     FILE KPim6GAPITargets.cmake
0122     NAMESPACE KPim6::
0123 )
0124
0125 install(FILES
0126     "${CMAKE_CURRENT_BINARY_DIR}/kgapi_version.h"
0127     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI"
0128     COMPONENT Devel
0129 )
0130
0131
0132
0133 ecm_qt_install_logging_categories(
0134         EXPORT LIBKGAPI
0135         FILE libkgapi.categories
0136         DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0137         )
0138
0139
0140 ecm_install_po_files_as_qm(poqm)
0141
0142 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)