pim/ksmtp/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.0")
0005
0006 project(KSMTP VERSION ${PIM_VERSION})
0007
0008
0009 # ECM setup
0010 set(KF_MIN_VERSION "5.246.0")
0011 set(QT_REQUIRED_VERSION "6.6.0")
0012 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDECompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateExportHeader)
0020 include(ECMGenerateHeaders)
0021
0022 include(ECMSetupVersion)
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0027 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0028
0029 include(ECMQtDeclareLoggingCategory)
0030 include(ECMDeprecationSettings)
0031
0032 include(ECMAddQch)
0033
0034
0035 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0036 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0037
0038
0039 set(KSMTP_LIB_VERSION ${PIM_VERSION})
0040
0041 ecm_setup_version(PROJECT VARIABLE_PREFIX KSMTP
0042     VERSION_HEADER ${KSMTP_BINARY_DIR}/src/ksmtp_version.h
0043     PACKAGE_VERSION_FILE ${KSMTP_BINARY_DIR}/KPim6SMTPConfigVersion.cmake
0044     SOVERSION 6
0045 )
0046
0047
0048 ############ Find packages ############
0049 find_package(Qt6Network ${QT_REQUIRED_VERSION} REQUIRED)
0050 find_package(KF6CoreAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0051 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KF6KIO ${KF_MIN_VERSION} CONFIG REQUIRED)
0053
0054 find_package(Sasl2)
0055 set_package_properties(Sasl2 PROPERTIES TYPE REQUIRED)
0056
0057 ########### CMake Config Files ############
0058
0059
0060 add_definitions(-DTRANSLATION_DOMAIN=\"libksmtp6\")
0061 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.248.0)
0062
0063 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0064
0065 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0066 if (USE_UNITY_CMAKE_SUPPORT)
0067     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0068 endif()
0069
0070
0071 ########### Targets ###########
0072 add_subdirectory(src)
0073
0074 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6SMTP")
0075 if (BUILD_QCH)
0076     ecm_install_qch_export(
0077         TARGETS KPim6SMTP_QCH
0078         FILE KPim6SMTPQchTargets.cmake
0079         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0080         COMPONENT Devel
0081     )
0082     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6SMTPQchTargets.cmake\")")
0083 endif()
0084
0085 configure_package_config_file(
0086     "${KSMTP_SOURCE_DIR}/KPimSMTPConfig.cmake.in"
0087     "${KSMTP_BINARY_DIR}/KPim6SMTPConfig.cmake"
0088     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0089 )
0090
0091 if (BUILD_TESTING)
0092     add_subdirectory(autotests)
0093     add_subdirectory(tests)
0094 endif ()
0095
0096 ########### Install Files ############
0097 install(FILES
0098     "${KSMTP_BINARY_DIR}/KPim6SMTPConfig.cmake"
0099     "${KSMTP_BINARY_DIR}/KPim6SMTPConfigVersion.cmake"
0100     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0101     COMPONENT Devel
0102 )
0103
0104 install(EXPORT KPim6SMTPTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6SMTPTargets.cmake NAMESPACE KPim6::)
0105
0106 install(FILES
0107     ${KSMTP_BINARY_DIR}/src/ksmtp_version.h
0108     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KSMTP COMPONENT Devel
0109 )
0110
0111 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0112 ki18n_install(po)
0113 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)