pim/ksmtp/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.40")
0005
0006 project(KSMTP VERSION ${PIM_VERSION})
0007
0008
0009 # ECM setup
0010 set(KF_MIN_VERSION "5.248.0")
0011 set(QT_REQUIRED_VERSION "6.6.0")
0012 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDECompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateExportHeader)
0020 include(ECMGenerateHeaders)
0021
0022 include(ECMSetupVersion)
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0027 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0028
0029 include(ECMQtDeclareLoggingCategory)
0030 include(ECMDeprecationSettings)
0031 include(ECMFeatureSummary)
0032
0033 include(ECMAddQch)
0034
0035
0036 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0037 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0038
0039
0040 set(KSMTP_LIB_VERSION ${PIM_VERSION})
0041
0042 ecm_setup_version(PROJECT VARIABLE_PREFIX KSMTP
0043     VERSION_HEADER ${KSMTP_BINARY_DIR}/src/ksmtp_version.h
0044     PACKAGE_VERSION_FILE ${KSMTP_BINARY_DIR}/KPim6SMTPConfigVersion.cmake
0045     SOVERSION 6
0046 )
0047
0048
0049 ############ Find packages ############
0050 find_package(Qt6Network ${QT_REQUIRED_VERSION} REQUIRED)
0051 find_package(KF6CoreAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0053 find_package(KF6KIO ${KF_MIN_VERSION} CONFIG REQUIRED)
0054
0055 find_package(Sasl2)
0056 set_package_properties(Sasl2 PROPERTIES TYPE REQUIRED)
0057
0058 ########### CMake Config Files ############
0059
0060
0061 add_definitions(-DTRANSLATION_DOMAIN=\"libksmtp6\")
0062 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.249.0)
0063
0064 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0065
0066 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0067 if (USE_UNITY_CMAKE_SUPPORT)
0068     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0069 endif()
0070
0071
0072 ########### Targets ###########
0073 add_subdirectory(src)
0074
0075 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6SMTP")
0076 if (BUILD_QCH)
0077     ecm_install_qch_export(
0078         TARGETS KPim6SMTP_QCH
0079         FILE KPim6SMTPQchTargets.cmake
0080         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0081         COMPONENT Devel
0082     )
0083     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6SMTPQchTargets.cmake\")")
0084 endif()
0085
0086 configure_package_config_file(
0087     "${KSMTP_SOURCE_DIR}/KPimSMTPConfig.cmake.in"
0088     "${KSMTP_BINARY_DIR}/KPim6SMTPConfig.cmake"
0089     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0090 )
0091
0092 if (BUILD_TESTING)
0093     add_subdirectory(autotests)
0094     add_subdirectory(tests)
0095 endif ()
0096
0097 ########### Install Files ############
0098 install(FILES
0099     "${KSMTP_BINARY_DIR}/KPim6SMTPConfig.cmake"
0100     "${KSMTP_BINARY_DIR}/KPim6SMTPConfigVersion.cmake"
0101     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0102     COMPONENT Devel
0103 )
0104
0105 install(EXPORT KPim6SMTPTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6SMTPTargets.cmake NAMESPACE KPim6::)
0106
0107 install(FILES
0108     ${KSMTP_BINARY_DIR}/src/ksmtp_version.h
0109     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KSMTP COMPONENT Devel
0110 )
0111
0112 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0113 ki18n_install(po)
0114 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)