pim/kmime/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002 set(PIM_VERSION "6.0.0")
0003
0004 project(KMime VERSION ${PIM_VERSION})
0005
0006 # ECM setup
0007 set(KF_MIN_VERSION "5.246.0")
0008
0009 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0010 set(CMAKE_MODULE_PATH ${KMime_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0011
0012 include(KDEInstallDirs)
0013 include(KDECMakeSettings)
0014 include(KDECompilerSettings NO_POLICY_SCOPE)
0015
0016 include(ECMGenerateExportHeader)
0017
0018 include(ECMGenerateHeaders)
0019 include(ECMSetupVersion)
0020 include(FeatureSummary)
0021 include(ECMQtDeclareLoggingCategory)
0022 include(ECMDeprecationSettings)
0023 include(ECMAddQch)
0024
0025 set(KMIME_LIB_VERSION ${PIM_VERSION})
0026 set(QT_REQUIRED_VERSION "6.6.0")
0027
0028
0029 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Core)
0030
0031 ecm_setup_version(PROJECT VARIABLE_PREFIX KMIME
0032                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kmime_version.h"
0033                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6MimeConfigVersion.cmake"
0034                         SOVERSION 6
0035 )
0036
0037 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0038 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0039
0040 ########### Find packages ###########
0041 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0042 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0043 add_definitions(-DTRANSLATION_DOMAIN=\"libkmime6\")
0044 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0045 ecm_set_disabled_deprecation_versions(QT 6.6.0  KF 5.248.0)
0046
0047 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0048
0049 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0050 if (USE_UNITY_CMAKE_SUPPORT)
0051     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0052 endif()
0053
0054 ########### Targets ###########
0055 add_subdirectory(src)
0056 add_subdirectory(includes)
0057
0058 if(BUILD_TESTING)
0059     add_subdirectory(autotests)
0060     add_subdirectory(tests)
0061 endif()
0062
0063 ########### CMake Config Files ###########
0064 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6Mime")
0065 if (BUILD_QCH)
0066     ecm_install_qch_export(
0067         TARGETS KPim6Mime_QCH
0068         FILE KPim6MimeQchTargets.cmake
0069         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0070         COMPONENT Devel
0071     )
0072     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6MimeQchTargets.cmake\")")
0073 endif()
0074
0075
0076 configure_package_config_file(
0077     "${KMime_SOURCE_DIR}/KPimMimeConfig.cmake.in"
0078     "${KMime_BINARY_DIR}/KPim6MimeConfig.cmake"
0079     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0080     )
0081
0082 install(FILES
0083     "${KMime_BINARY_DIR}/KPim6MimeConfig.cmake"
0084     "${KMime_BINARY_DIR}/KPim6MimeConfigVersion.cmake"
0085     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0086     COMPONENT Devel
0087     )
0088
0089 install(EXPORT KPim6MimeTargets
0090     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0091     FILE KPim6MimeTargets.cmake
0092     NAMESPACE KPim6::
0093     )
0094
0095 install(FILES
0096     ${KMime_BINARY_DIR}/kmime_version.h
0097     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KMime/
0098     COMPONENT Devel
0099     )
0100
0101 ki18n_install(po)
0102 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)