pim/kmime/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002 set(PIM_VERSION "6.0.40")
0003
0004 project(KMime VERSION ${PIM_VERSION})
0005
0006 # ECM setup
0007 set(KF_MIN_VERSION "5.248.0")
0008
0009 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0010 set(CMAKE_MODULE_PATH ${KMime_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0011
0012 include(KDEInstallDirs)
0013 include(KDECMakeSettings)
0014 include(KDECompilerSettings NO_POLICY_SCOPE)
0015
0016 include(ECMGenerateExportHeader)
0017
0018 include(ECMGenerateHeaders)
0019 include(ECMSetupVersion)
0020 include(FeatureSummary)
0021 include(ECMQtDeclareLoggingCategory)
0022 include(ECMDeprecationSettings)
0023 include(ECMFeatureSummary)
0024 include(ECMAddQch)
0025
0026 set(KMIME_LIB_VERSION ${PIM_VERSION})
0027 set(QT_REQUIRED_VERSION "6.6.0")
0028
0029
0030 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Core)
0031
0032 ecm_setup_version(PROJECT VARIABLE_PREFIX KMIME
0033                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kmime_version.h"
0034                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6MimeConfigVersion.cmake"
0035                         SOVERSION 6
0036 )
0037
0038 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0039 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0040
0041 ########### Find packages ###########
0042 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0043 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0044 add_definitions(-DTRANSLATION_DOMAIN=\"libkmime6\")
0045 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0046 ecm_set_disabled_deprecation_versions(QT 6.6.0  KF 5.249.0)
0047
0048 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0049
0050 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0051 if (USE_UNITY_CMAKE_SUPPORT)
0052     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0053 endif()
0054
0055 ########### Targets ###########
0056 add_subdirectory(src)
0057 add_subdirectory(includes)
0058
0059 if(BUILD_TESTING)
0060     add_subdirectory(autotests)
0061     add_subdirectory(tests)
0062 endif()
0063
0064 ########### CMake Config Files ###########
0065 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6Mime")
0066 if (BUILD_QCH)
0067     ecm_install_qch_export(
0068         TARGETS KPim6Mime_QCH
0069         FILE KPim6MimeQchTargets.cmake
0070         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0071         COMPONENT Devel
0072     )
0073     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6MimeQchTargets.cmake\")")
0074 endif()
0075
0076
0077 configure_package_config_file(
0078     "${KMime_SOURCE_DIR}/KPimMimeConfig.cmake.in"
0079     "${KMime_BINARY_DIR}/KPim6MimeConfig.cmake"
0080     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0081     )
0082
0083 install(FILES
0084     "${KMime_BINARY_DIR}/KPim6MimeConfig.cmake"
0085     "${KMime_BINARY_DIR}/KPim6MimeConfigVersion.cmake"
0086     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0087     COMPONENT Devel
0088     )
0089
0090 install(EXPORT KPim6MimeTargets
0091     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0092     FILE KPim6MimeTargets.cmake
0093     NAMESPACE KPim6::
0094     )
0095
0096 install(FILES
0097     ${KMime_BINARY_DIR}/kmime_version.h
0098     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KMime/
0099     COMPONENT Devel
0100     )
0101
0102 ki18n_install(po)
0103 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)