pim/kcalutils/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004
0005 set(PIM_VERSION "6.0.0")
0006 project(KCalUtils VERSION ${PIM_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.246.0")
0010 set(QT_REQUIRED_VERSION "6.6.0")
0011
0012 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0013 set(CMAKE_MODULE_PATH ${KCalUtils_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDECompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateHeaders)
0020 include(ECMGenerateExportHeader)
0021
0022 include(ECMSetupVersion)
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0027 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0028
0029 include(ECMQtDeclareLoggingCategory)
0030 include(ECMDeprecationSettings)
0031
0032 include(KPIMGrantleeMacros)
0033 include(ECMAddQch)
0034
0035
0036 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0037 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0038
0039 set(CALENDARUTILS_LIB_VERSION ${PIM_VERSION})
0040 set(IDENTITYMANAGER_LIB_VERSION "6.0.0")
0041 ecm_setup_version(PROJECT VARIABLE_PREFIX KCALUTILS
0042                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/kcalutils_version.h"
0043                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarUtilsConfigVersion.cmake"
0044                         SOVERSION 6
0045 )
0046
0047 ########### Find packages ###########
0048 find_package(KF6CoreAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0049 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0050 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0051 find_package(KF6WidgetsAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KF6IconThemes ${KF_MIN_VERSION} CONFIG REQUIRED)
0053
0054 find_package(KF6TextTemplate CONFIG REQUIRED)
0055
0056 find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
0057 find_package(KPim6IdentityManagementCore ${IDENTITYMANAGER_LIB_VERSION} CONFIG REQUIRED)
0058 add_definitions(-DTRANSLATION_DOMAIN=\"libkcalutils6\")
0059
0060 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0061 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.248.0)
0062
0063
0064 if(BUILD_TESTING)
0065   add_definitions(-DBUILD_TESTING)
0066 endif()
0067 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0068
0069 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0070 if (USE_UNITY_CMAKE_SUPPORT)
0071     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0072     add_definitions(-DCOMPILE_WITH_UNITY_CMAKE_SUPPORT)
0073 endif()
0074 add_subdirectory(src)
0075
0076 if(BUILD_TESTING)
0077   add_subdirectory(autotests)
0078 endif()
0079
0080 ########### CMake Config Files ###########
0081 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6CalendarUtils")
0082 if (BUILD_QCH)
0083     ecm_install_qch_export(
0084         TARGETS KPim6CalendarUtils_QCH
0085         FILE KPim6CalendarUtilsQchTargets.cmake
0086         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0087         COMPONENT Devel
0088     )
0089     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6CalendarUtilsQchTargets.cmake\")")
0090 endif()
0091
0092 configure_package_config_file(
0093   "${CMAKE_CURRENT_SOURCE_DIR}/KPimCalendarUtilsConfig.cmake.in"
0094   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarUtilsConfig.cmake"
0095   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0096 )
0097
0098 install(FILES
0099   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarUtilsConfig.cmake"
0100   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarUtilsConfigVersion.cmake"
0101   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0102   COMPONENT Devel
0103 )
0104
0105 install(EXPORT KPim6CalendarUtilsTargets
0106   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0107   FILE KPim6CalendarUtilsTargets.cmake
0108   NAMESPACE KPim6::
0109 )
0110
0111 install(FILES
0112   ${CMAKE_CURRENT_BINARY_DIR}/src/kcalutils_version.h
0113   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KCalUtils/
0114   COMPONENT Devel
0115 )
0116
0117 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0118 ki18n_install(po)
0119 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)