pim/kcalutils/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004
0005 set(PIM_VERSION "6.0.40")
0006 project(KCalUtils VERSION ${PIM_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.248.0")
0010 set(QT_REQUIRED_VERSION "6.6.0")
0011
0012 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0013 set(CMAKE_MODULE_PATH ${KCalUtils_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDECompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateHeaders)
0020 include(ECMGenerateExportHeader)
0021
0022 include(ECMSetupVersion)
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0027 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0028
0029 include(ECMQtDeclareLoggingCategory)
0030 include(ECMDeprecationSettings)
0031 include(ECMFeatureSummary)
0032
0033 include(KPIMGrantleeMacros)
0034 include(ECMAddQch)
0035
0036
0037 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0038 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0039
0040 set(CALENDARUTILS_LIB_VERSION ${PIM_VERSION})
0041 set(IDENTITYMANAGER_LIB_VERSION "6.0.40")
0042 ecm_setup_version(PROJECT VARIABLE_PREFIX KCALUTILS
0043                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/kcalutils_version.h"
0044                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarUtilsConfigVersion.cmake"
0045                         SOVERSION 6
0046 )
0047
0048 ########### Find packages ###########
0049 find_package(KF6CoreAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0050 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0051 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KF6WidgetsAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0053 find_package(KF6IconThemes ${KF_MIN_VERSION} CONFIG REQUIRED)
0054
0055 find_package(KF6TextTemplate CONFIG REQUIRED)
0056
0057 find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
0058 find_package(KPim6IdentityManagementCore ${IDENTITYMANAGER_LIB_VERSION} CONFIG REQUIRED)
0059 add_definitions(-DTRANSLATION_DOMAIN=\"libkcalutils6\")
0060
0061 add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
0062 ecm_set_disabled_deprecation_versions(QT 6.6.0 KF 5.249.0)
0063
0064
0065 if(BUILD_TESTING)
0066   add_definitions(-DBUILD_TESTING)
0067 endif()
0068 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0069
0070 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0071 if (USE_UNITY_CMAKE_SUPPORT)
0072     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0073     add_definitions(-DCOMPILE_WITH_UNITY_CMAKE_SUPPORT)
0074 endif()
0075 add_subdirectory(src)
0076
0077 if(BUILD_TESTING)
0078   add_subdirectory(autotests)
0079 endif()
0080
0081 ########### CMake Config Files ###########
0082 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6CalendarUtils")
0083 if (BUILD_QCH)
0084     ecm_install_qch_export(
0085         TARGETS KPim6CalendarUtils_QCH
0086         FILE KPim6CalendarUtilsQchTargets.cmake
0087         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0088         COMPONENT Devel
0089     )
0090     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6CalendarUtilsQchTargets.cmake\")")
0091 endif()
0092
0093 configure_package_config_file(
0094   "${CMAKE_CURRENT_SOURCE_DIR}/KPimCalendarUtilsConfig.cmake.in"
0095   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarUtilsConfig.cmake"
0096   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0097 )
0098
0099 install(FILES
0100   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarUtilsConfig.cmake"
0101   "${CMAKE_CURRENT_BINARY_DIR}/KPim6CalendarUtilsConfigVersion.cmake"
0102   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0103   COMPONENT Devel
0104 )
0105
0106 install(EXPORT KPim6CalendarUtilsTargets
0107   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0108   FILE KPim6CalendarUtilsTargets.cmake
0109   NAMESPACE KPim6::
0110 )
0111
0112 install(FILES
0113   ${CMAKE_CURRENT_BINARY_DIR}/src/kcalutils_version.h
0114   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/KCalUtils/
0115   COMPONENT Devel
0116 )
0117
0118 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0119 ki18n_install(po)
0120 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)