pim/eventviews/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.0")
0005
0006 project(eventviews VERSION ${PIM_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.246.0")
0010 set(QT_REQUIRED_VERSION "6.6.0")
0011
0012 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDECompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateExportHeader)
0020 include(ECMSetupVersion)
0021 include(ECMGenerateHeaders)
0022
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0027 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0028 include(ECMQtDeclareLoggingCategory)
0029 include(ECMDeprecationSettings)
0030 include(ECMAddTests)
0031 include(ECMAddQch)
0032 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0033 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0034
0035 set(EVENTVIEW_LIB_VERSION ${PIM_VERSION})
0036 set(CALENDARUTILS_LIB_VERSION "6.0.0")
0037 set(AKONADI_LIB_VERSION "6.0.0")
0038 set(AKONADICALENDAR_LIB_VERSION "6.0.0")
0039 set(KMIME_LIB_VERSION "6.0.0")
0040 set(LIBKDEPIM_LIB_VERSION "6.0.0")
0041 set(CALENDARSUPPORT_LIB_VERSION "6.0.0")
0042
0043 find_package(KPim6Akonadi ${AKONADI_LIB_VERSION} CONFIG REQUIRED)
0044 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Widgets)
0045 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0046 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0047 find_package(KF6GuiAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0048 find_package(KF6IconThemes ${KF_MIN_VERSION} CONFIG REQUIRED)
0049 find_package(KF6ItemModels ${KF_MIN_VERSION} CONFIG REQUIRED)
0050 find_package(KF6Service ${KF_MIN_VERSION} CONFIG REQUIRED)
0051 find_package(KF6Completion ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KF6Holidays ${KF_MIN_VERSION} CONFIG REQUIRED)
0053 find_package(KF6Contacts ${KF_MIN_VERSION} CONFIG REQUIRED)
0054 find_package(KF6ConfigWidgets ${KF_MIN_VERSION} CONFIG REQUIRED)
0055
0056 set(KDIAGRAM_LIB_VERSION "3.0.0")
0057 find_package(KGantt6 ${KDIAGRAM_LIB_VERSION} CONFIG REQUIRED)
0058
0059 find_package(KPim6Libkdepim ${LIBKDEPIM_LIB_VERSION} CONFIG REQUIRED)
0060 find_package(KPim6CalendarUtils ${CALENDARUTILS_LIB_VERSION} CONFIG REQUIRED)
0061 find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
0062 find_package(KPim6CalendarSupport ${CALENDARSUPPORT_LIB_VERSION} CONFIG REQUIRED)
0063 find_package(KPim6AkonadiCalendar ${AKONADICALENDAR_LIB_VERSION} CONFIG REQUIRED)
0064 find_package(KPim6Mime ${KMIME_LIB_VERSION} CONFIG REQUIRED)
0065
0066 ecm_setup_version(PROJECT VARIABLE_PREFIX EVENTVIEWS
0067                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/eventviews_version.h"
0068                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6EventViewsConfigVersion.cmake"
0069                         SOVERSION 6
0070 )
0071 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0072
0073 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0074 if (USE_UNITY_CMAKE_SUPPORT)
0075     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0076     add_definitions(-DCOMPILE_WITH_UNITY_CMAKE_SUPPORT)
0077 endif()
0078
0079
0080 ########### Targets ###########
0081
0082 if(BUILD_TESTING)
0083   add_definitions(-DBUILD_TESTING)
0084 endif()
0085
0086 ecm_set_disabled_deprecation_versions(QT 6.6
0087      KF 5.248.0
0088 )
0089 add_subdirectory(src)
0090 if(BUILD_TESTING)
0091   find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Test)
0092   add_subdirectory(tests)
0093 endif()
0094
0095
0096 ########### CMake Config Files ###########
0097 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6EventViews")
0098 if (BUILD_QCH)
0099     ecm_install_qch_export(
0100         TARGETS KPim6EventViews_QCH
0101         FILE KPim6EventViewsQchTargets.cmake
0102         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0103         COMPONENT Devel
0104     )
0105     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6EventViewsQchTargets.cmake\")")
0106 endif()
0107
0108 configure_package_config_file(
0109   "${CMAKE_CURRENT_SOURCE_DIR}/KPimEventViewsConfig.cmake.in"
0110   "${CMAKE_CURRENT_BINARY_DIR}/KPim6EventViewsConfig.cmake"
0111   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0112 )
0113
0114 install(FILES
0115   "${CMAKE_CURRENT_BINARY_DIR}/KPim6EventViewsConfig.cmake"
0116   "${CMAKE_CURRENT_BINARY_DIR}/KPim6EventViewsConfigVersion.cmake"
0117   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0118   COMPONENT Devel
0119 )
0120
0121 install(EXPORT KPim6EventViewsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0122     FILE KPim6EventViewsTargets.cmake NAMESPACE KPim6::)
0123
0124 install(FILES
0125   ${CMAKE_CURRENT_BINARY_DIR}/src/eventviews_version.h
0126   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/EventViews COMPONENT Devel
0127 )
0128
0129 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0130 ki18n_install(po)
0131 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)