pim/eventviews/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0004 set(PIM_VERSION "6.0.40")
0005
0006 project(eventviews VERSION ${PIM_VERSION})
0007
0008 # ECM setup
0009 set(KF_MIN_VERSION "5.248.0")
0010 set(QT_REQUIRED_VERSION "6.6.0")
0011
0012 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDECompilerSettings NO_POLICY_SCOPE)
0018
0019 include(ECMGenerateExportHeader)
0020 include(ECMSetupVersion)
0021 include(ECMGenerateHeaders)
0022
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0027 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0028 include(ECMQtDeclareLoggingCategory)
0029 include(ECMDeprecationSettings)
0030 include(ECMFeatureSummary)
0031 include(ECMAddTests)
0032 include(ECMAddQch)
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 set(EVENTVIEW_LIB_VERSION ${PIM_VERSION})
0037 set(CALENDARUTILS_LIB_VERSION "6.0.40")
0038 set(AKONADI_LIB_VERSION "6.0.40")
0039 set(AKONADICALENDAR_LIB_VERSION "6.0.40")
0040 set(KMIME_LIB_VERSION "6.0.40")
0041 set(LIBKDEPIM_LIB_VERSION "6.0.40")
0042 set(CALENDARSUPPORT_LIB_VERSION "6.0.40")
0043
0044 find_package(KPim6Akonadi ${AKONADI_LIB_VERSION} CONFIG REQUIRED)
0045 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Widgets)
0046 find_package(KF6I18n ${KF_MIN_VERSION} CONFIG REQUIRED)
0047 find_package(KF6Codecs ${KF_MIN_VERSION} CONFIG REQUIRED)
0048 find_package(KF6GuiAddons ${KF_MIN_VERSION} CONFIG REQUIRED)
0049 find_package(KF6IconThemes ${KF_MIN_VERSION} CONFIG REQUIRED)
0050 find_package(KF6ItemModels ${KF_MIN_VERSION} CONFIG REQUIRED)
0051 find_package(KF6Service ${KF_MIN_VERSION} CONFIG REQUIRED)
0052 find_package(KF6Completion ${KF_MIN_VERSION} CONFIG REQUIRED)
0053 find_package(KF6Holidays ${KF_MIN_VERSION} CONFIG REQUIRED)
0054 find_package(KF6Contacts ${KF_MIN_VERSION} CONFIG REQUIRED)
0055 find_package(KF6ConfigWidgets ${KF_MIN_VERSION} CONFIG REQUIRED)
0056
0057 set(KDIAGRAM_LIB_VERSION "3.0.0")
0058 find_package(KGantt6 ${KDIAGRAM_LIB_VERSION} CONFIG REQUIRED)
0059
0060 find_package(KPim6Libkdepim ${LIBKDEPIM_LIB_VERSION} CONFIG REQUIRED)
0061 find_package(KPim6CalendarUtils ${CALENDARUTILS_LIB_VERSION} CONFIG REQUIRED)
0062 find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
0063 find_package(KPim6CalendarSupport ${CALENDARSUPPORT_LIB_VERSION} CONFIG REQUIRED)
0064 find_package(KPim6AkonadiCalendar ${AKONADICALENDAR_LIB_VERSION} CONFIG REQUIRED)
0065 find_package(KPim6Mime ${KMIME_LIB_VERSION} CONFIG REQUIRED)
0066
0067 ecm_setup_version(PROJECT VARIABLE_PREFIX EVENTVIEWS
0068                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/eventviews_version.h"
0069                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6EventViewsConfigVersion.cmake"
0070                         SOVERSION 6
0071 )
0072 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0073
0074 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0075 if (USE_UNITY_CMAKE_SUPPORT)
0076     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0077     add_definitions(-DCOMPILE_WITH_UNITY_CMAKE_SUPPORT)
0078 endif()
0079
0080
0081 ########### Targets ###########
0082
0083 if(BUILD_TESTING)
0084   add_definitions(-DBUILD_TESTING)
0085 endif()
0086
0087 ecm_set_disabled_deprecation_versions(QT 6.6
0088      KF 5.249.0
0089 )
0090 add_subdirectory(src)
0091 if(BUILD_TESTING)
0092   find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Test)
0093   add_subdirectory(tests)
0094 endif()
0095
0096
0097 ########### CMake Config Files ###########
0098 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6EventViews")
0099 if (BUILD_QCH)
0100     ecm_install_qch_export(
0101         TARGETS KPim6EventViews_QCH
0102         FILE KPim6EventViewsQchTargets.cmake
0103         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0104         COMPONENT Devel
0105     )
0106     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6EventViewsQchTargets.cmake\")")
0107 endif()
0108
0109 configure_package_config_file(
0110   "${CMAKE_CURRENT_SOURCE_DIR}/KPimEventViewsConfig.cmake.in"
0111   "${CMAKE_CURRENT_BINARY_DIR}/KPim6EventViewsConfig.cmake"
0112   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0113 )
0114
0115 install(FILES
0116   "${CMAKE_CURRENT_BINARY_DIR}/KPim6EventViewsConfig.cmake"
0117   "${CMAKE_CURRENT_BINARY_DIR}/KPim6EventViewsConfigVersion.cmake"
0118   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0119   COMPONENT Devel
0120 )
0121
0122 install(EXPORT KPim6EventViewsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0123     FILE KPim6EventViewsTargets.cmake NAMESPACE KPim6::)
0124
0125 install(FILES
0126   ${CMAKE_CURRENT_BINARY_DIR}/src/eventviews_version.h
0127   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/EventViews COMPONENT Devel
0128 )
0129
0130 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0131 ki18n_install(po)
0132 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)