alkimia/autotests/CMakeLists.txt

0001 include(ECMAddTests)
0002 set(TEST_LIB
0003     alkimia
0004     alkimia-internal
0005     ${QT_USE_LIBSPREFIX}Test
0006     ${QT_USE_LIBSPREFIX}Core
0007     ${QT_USE_LIBSPREFIX}DBus
0008     ${MP_LIBRARIES}
0009 )
0010
0011 if(BUILD_QT4)
0012     list(APPEND TEST_LIB ${KDE4_KDECORE_LIBS})
0013 endif()
0014
0015 ecm_add_tests(
0016     alkonlinequotesourcetest.cpp
0017     alkvaluetest.cpp
0018     alkquoteitemtest.cpp
0019     alkcompanytest.cpp
0020     alkexceptiontest.cpp
0021     LINK_LIBRARIES
0022     alkimia ${TEST_LIB}
0023 )
0024
0025 ecm_add_test(
0026     alkonlinequotetest.cpp
0027     ../src/alkquotereceiver.cpp
0028     LINK_LIBRARIES ${TEST_LIB}
0029     TEST_NAME alkonlinequotestest
0030 )
0031
0032 ecm_add_test(
0033     alkdateformattest.cpp
0034     LINK_LIBRARIES ${TEST_LIB}
0035     TEST_NAME alkdateformattest
0036 )
0037
0038 #
0039 # cmake install test
0040 #
0041 set(TEMP_INSTALL_DIR ${CMAKE_BINARY_DIR}/tmp)
0042
0043 if(CMAKE_CROSSCOMPILING)
0044     if(NOT TARGET_SYSROOT)
0045         execute_process(
0046             COMMAND ${CMAKE_C_COMPILER} --print-sysroot
0047             OUTPUT_VARIABLE TARGET_SYSROOT
0048             ERROR_VARIABLE ERROR
0049             RESULT_VARIABLE RESULT
0050         )
0051         if(RESULT)
0052             set(ENABLE_CLIENT_PACKAGE_TEST 0)
0053             message(WARNING "disabled client package build, because sysroot could not be fetched from compiler - error is ${ERROR_VARIABLE}")
0054         endif()
0055         string(REPLACE "\n" "/${TARGET_PREFIX}" TARGET_SYSROOT "${TARGET_SYSROOT}")
0056     endif()
0057 endif()
0058
0059 if(ENABLE_CLIENT_PACKAGE_TEST)
0060     # clean local install directories used by client build/install test
0061     add_test(
0062         NAME test-install-local-clean
0063         COMMAND ${CMAKE_COMMAND} -E remove_directory ${TEMP_INSTALL_DIR}
0064         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
0065     )
0066
0067     # install dbus in local directoy for client build/install test
0068     add_test(
0069         NAME test-install-local
0070         COMMAND ${CMAKE_MAKE_PROGRAM} install DESTDIR=${TEMP_INSTALL_DIR}
0071         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
0072     )
0073
0074     # build/install a client package using dbus cmake package support from this build
0075     add_test(
0076         NAME test-install-build-client-package
0077         COMMAND ${CMAKE_CTEST_COMMAND}
0078             --build-and-test
0079             ${CMAKE_CURRENT_SOURCE_DIR}/client-package
0080             ${CMAKE_CURRENT_BINARY_DIR}/client-package
0081             --build-config "${CMAKE_BUILD_TYPE}"
0082             --build-generator ${CMAKE_GENERATOR}
0083             --build-makeprogram ${CMAKE_MAKE_PROGRAM}
0084             --build-target install
0085             --build-options
0086                 #--trace-expand
0087                 -DALKIMIA_PATH_SUFFIX=${ALKIMIA_PATH_SUFFIX}
0088                 -DLibAlkimia${ALKIMIA_PATH_SUFFIX}_DIR=${TEMP_INSTALL_DIR}${CMAKE_INSTALL_PREFIX}/${CMAKECONFIG_INSTALL_DIR}
0089                 -DCHECK_VERSION=${PROJECT_VERSION}
0090                 -DCMAKE_CROSSCOMPILING=${CMAKE_CROSSCOMPILING}
0091                 -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
0092                 -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
0093                 -DCMAKE_INSTALL_PREFIX:PATH=${TEMP_INSTALL_DIR}${CMAKE_INSTALL_PREFIX}
0094                 -DCMAKE_FIND_ROOT_PATH=${TARGET_SYSROOT};${TEMP_INSTALL_DIR}${CMAKE_INSTALL_PREFIX}
0095                 -DCMAKE_FIND_ROOT_PATH_MODE_PROGRAM=NEVER
0096                 -DCMAKE_FIND_ROOT_PATH_MODE_LIBRARY=ONLY
0097                 -DCMAKE_FIND_ROOT_PATH_MODE_INCLUDE=ONLY
0098                 -DCMAKE_SYSTEM_NAME=${CMAKE_SYSTEM_NAME}
0099                 -DCMAKE_SYSTEM_PROCESSOR=${CMAKE_SYSTEM_PROCESSOR}
0100         )
0101
0102     set_property(TEST test-install-build-client-package APPEND PROPERTY DEPENDS test-install-local-clean test-install-local)
0103 endif()