alkimia/autotests/CMakeLists.txt

0001 include(ECMAddTests)
0002 set(TEST_LIB
0003     Qt${QT_MAJOR_VERSION}::Test
0004     Qt${QT_MAJOR_VERSION}::Core
0005     Qt${QT_MAJOR_VERSION}::DBus
0006     ${MP_LIBRARIES}
0007     alkimia-internal
0008     alkimia
0009 )
0010
0011 ecm_add_tests(
0012     alkonlinequotesourcetest.cpp
0013     alkvaluetest.cpp
0014     alkquoteitemtest.cpp
0015     alkcompanytest.cpp
0016     alkexceptiontest.cpp
0017     LINK_LIBRARIES
0018     ${TEST_LIB}
0019 )
0020
0021 ecm_add_test(
0022     alkonlinequotetest.cpp
0023     ../src/alkquotereceiver.cpp
0024     LINK_LIBRARIES ${TEST_LIB}
0025     TEST_NAME alkonlinequotestest
0026 )
0027 set_property(TEST alkonlinequotestest PROPERTY ENVIRONMENT "QTWEBENGINE_DISABLE_SANDBOX=1")
0028
0029 ecm_add_test(
0030     alkdateformattest.cpp
0031     LINK_LIBRARIES ${TEST_LIB}
0032     TEST_NAME alkdateformattest
0033 )
0034
0035 ecm_add_test(
0036     alkonlinequoteprivatetest.cpp
0037     alkonlinequoteprivatetest.qrc
0038     LINK_LIBRARIES ${TEST_LIB}
0039     TEST_NAME alkonlinequoteprivatetest
0040 )
0041
0042 ecm_add_test(
0043     alknewstuffenginetest.cpp
0044     LINK_LIBRARIES alkimia alkimia-internal ${KF_NEWSTUFF_LIB}
0045     TEST_NAME alknewstuffenginetest
0046 )
0047
0048 #
0049 # cmake install test
0050 #
0051 set(TEMP_INSTALL_DIR ${CMAKE_BINARY_DIR}/tmp)
0052
0053 if(CMAKE_CROSSCOMPILING)
0054     if(NOT TARGET_SYSROOT)
0055         execute_process(
0056             COMMAND ${CMAKE_C_COMPILER} --print-sysroot
0057             OUTPUT_VARIABLE TARGET_SYSROOT
0058             ERROR_VARIABLE ERROR
0059             RESULT_VARIABLE RESULT
0060         )
0061         if(RESULT)
0062             set(ENABLE_CLIENT_PACKAGE_TEST 0)
0063             message(WARNING "disabled client package build, because sysroot could not be fetched from compiler - error is ${ERROR_VARIABLE}")
0064         endif()
0065         string(REPLACE "\n" "/${TARGET_PREFIX}" TARGET_SYSROOT "${TARGET_SYSROOT}")
0066     endif()
0067 endif()
0068
0069 if(ENABLE_CLIENT_PACKAGE_TEST)
0070     # clean local install directories used by client build/install test
0071     add_test(
0072         NAME test-install-local-clean
0073         COMMAND ${CMAKE_COMMAND} -E remove_directory ${TEMP_INSTALL_DIR}
0074         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
0075     )
0076
0077     # install dbus in local directoy for client build/install test
0078     add_test(
0079         NAME test-install-local
0080         COMMAND ${CMAKE_MAKE_PROGRAM} install DESTDIR=${TEMP_INSTALL_DIR}
0081         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
0082     )
0083
0084     set(FIND_ROOT_PATH "${TARGET_SYSROOT};${TEMP_INSTALL_DIR}${CMAKE_INSTALL_PREFIX}")
0085     # build/install a client package using dbus cmake package support from this build
0086     add_test(
0087         NAME test-install-build-client-package
0088         COMMAND ${CMAKE_CTEST_COMMAND}
0089             --build-and-test
0090             ${CMAKE_CURRENT_SOURCE_DIR}/client-package
0091             ${CMAKE_CURRENT_BINARY_DIR}/client-package
0092             --build-config "${CMAKE_BUILD_TYPE}"
0093             --build-generator ${CMAKE_GENERATOR}
0094             --build-makeprogram ${CMAKE_MAKE_PROGRAM}
0095             --build-target install
0096             --build-options
0097                 #--trace-expand
0098                 -DALKIMIA_PATH_SUFFIX=${ALKIMIA_PATH_SUFFIX}
0099                 -DLibAlkimia${ALKIMIA_PATH_SUFFIX}_DIR=${TEMP_INSTALL_DIR}${CMAKE_INSTALL_PREFIX}/${CMAKECONFIG_INSTALL_DIR}
0100                 -DCHECK_VERSION=${PROJECT_VERSION}
0101                 -DCMAKE_CROSSCOMPILING=${CMAKE_CROSSCOMPILING}
0102                 -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
0103                 -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
0104                 -DCMAKE_INSTALL_PREFIX:PATH=${TEMP_INSTALL_DIR}${CMAKE_INSTALL_PREFIX}
0105                 -DCMAKE_FIND_ROOT_PATH:PATH=${FIND_ROOT_PATH}
0106                 -DCMAKE_FIND_ROOT_PATH_MODE_PROGRAM=NEVER
0107                 -DCMAKE_FIND_ROOT_PATH_MODE_LIBRARY=ONLY
0108                 -DCMAKE_FIND_ROOT_PATH_MODE_INCLUDE=ONLY
0109                 -DCMAKE_SYSTEM_NAME=${CMAKE_SYSTEM_NAME}
0110                 -DCMAKE_SYSTEM_PROCESSOR=${CMAKE_SYSTEM_PROCESSOR}
0111         )
0112
0113     set_property(TEST test-install-build-client-package APPEND PROPERTY DEPENDS test-install-local-clean test-install-local)
0114 endif()