kweathercore/src/CMakeLists.txt

0001 set(kweathercore_LIB_SRCS
0002     locationquery.cpp
0003     locationqueryresult.cpp
0004     weatherforecastsource.cpp
0005     weatherforecast.cpp
0006     hourlyweatherforecast.cpp
0007     dailyweatherforecast.cpp
0008     geotimezone.cpp
0009     pendingweatherforecast.cpp
0010     sunrise.cpp
0011     sunrisesource.cpp
0012     alertinfo.cpp
0013     alertfeedentry.cpp
0014     alertentry.cpp
0015     alertmanager.cpp
0016     feedparser.cpp
0017     pendingalerts.cpp
0018     pendingcap.cpp
0019     capparser.cpp)
0020
0021
0022 add_library(KF5KWeatherCore ${kweathercore_LIB_SRCS})
0023 generate_export_header(KF5KWeatherCore BASE_NAME KWeatherCore EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/kweathercore/kweathercore_export.h)
0024 add_library(KF5::KWeatherCore ALIAS KF5KWeatherCore)
0025 set(kweathercore_BUILD_INCLUDE_DIRS ${KWeatherCore_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR})
0026 target_include_directories(KF5KWeatherCore PUBLIC "$<BUILD_INTERFACE:${kweathercore_BUILD_INCLUDE_DIRS}>")
0027 target_include_directories(KF5KWeatherCore INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}/KWeatherCore>")
0028
0029 target_link_libraries(KF5KWeatherCore
0030 PUBLIC Qt5::Core
0031 PRIVATE Qt5::Network
0032         KF5::I18n
0033         Qt5::Positioning
0034 )
0035
0036 set_target_properties(KF5KWeatherCore PROPERTIES VERSION ${KWEATHERCORE_VERSION_STRING}
0037                                                  SOVERSION ${KWEATHERCORE_SOVERSION}
0038                                                  EXPORT_NAME KWeatherCore
0039 )
0040
0041 ecm_generate_headers(KWeatherCore_CamelCase_HEADERS
0042     HEADER_NAMES
0043     LocationQuery
0044     LocationQueryResult
0045     DailyWeatherForecast
0046     HourlyWeatherForecast
0047     PendingWeatherForecast
0048     Sunrise
0049     SunriseSource
0050     WeatherForecast
0051     WeatherForecastSource
0052     GeoTimezone
0053     AlertInfo
0054     AlertEntry
0055     AlertFeedEntry
0056     AlertManager
0057     PendingAlerts
0058     PendingCAP
0059
0060     PREFIX KWeatherCore
0061     REQUIRED_HEADERS KWeatherCore_HEADERS
0062 )
0063 install(FILES ${KWeatherCore_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KWeatherCore/KWeatherCore COMPONENT Devel)
0064
0065 install(TARGETS KF5KWeatherCore EXPORT KF5KWeatherCoreTargets ${KF5_INSTALL_TARGETS_DEFAULT_ARGS})
0066 install(FILES
0067   ${CMAKE_CURRENT_BINARY_DIR}/kweathercore/kweathercore_export.h
0068   ${KWeatherCore_HEADERS}
0069   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KWeatherCore/kweathercore COMPONENT Devel
0070 )
0071
0072 if(BUILD_QCH)
0073     ecm_add_qch(
0074         KF5KWeatherCore_QCH
0075         NAME KWeatherCore
0076         BASE_NAME KF5KWeatherCore
0077         VERSION ${KF5_VERSION}
0078         ORG_DOMAIN org.kde
0079         SOURCES # using only public headers, to cover only public API
0080             ${KWeatherCore_HEADERS}
0081         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0082         LINK_QCHS
0083             Qt5Core_QCH
0084         INCLUDE_DIRS
0085             ${kweathercore_BUILD_INCLUDE_DIRS}
0086         BLANK_MACROS
0087             KWEATHERCORE_EXPORT
0088             KWEATHERCORE_DEPRECATED
0089             KWEATHERCORE_DEPRECATED_EXPORT
0090         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0091         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0092         COMPONENT Devel
0093         )
0094 endif()
0095
0096 include(ECMGeneratePriFile)
0097 ecm_generate_pri_file(
0098     BASE_NAME KWeatherCore
0099     LIB_NAME KF5KWeatherCore
0100     DEPS "core"
0101     FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF5}/KWeatherCore
0102 )
0103 install(FILES ${PRI_FILENAME}
0104         DESTINATION ${ECM_MKSPECS_INSTALL_DIR})