kweathercore/src/CMakeLists.txt

0001 set(kweathercore_LIB_SRCS
0002     locationquery.cpp
0003     locationquery.h
0004     locationqueryreply.cpp
0005     locationqueryreply.h
0006     locationqueryresult.cpp
0007     locationqueryresult.h
0008     weatherforecastsource.cpp
0009     weatherforecastsource.h
0010     weatherforecast.cpp
0011     weatherforecast.h
0012     hourlyweatherforecast.cpp
0013     hourlyweatherforecast.h
0014     dailyweatherforecast.cpp
0015     dailyweatherforecast.h
0016     geotimezone.cpp
0017     geotimezone.h
0018     kweathercore.cpp
0019     kweathercore_p.h
0020     metnoparser.cpp
0021     metnoparser_p.h
0022     pendingweatherforecast.cpp
0023     pendingweatherforecast.h
0024     pendingweatherforecast_p.h
0025     capalertinfo.cpp
0026     capalertinfo.h
0027     alertfeedentry.cpp
0028     alertfeedentry.h
0029     capalertmessage.cpp
0030     capalertmessage.h
0031     alertmanager.cpp
0032     alertmanager.h
0033     feedparser.cpp
0034     feedparser.h
0035     pendingalerts.cpp
0036     pendingalerts.h
0037     pendingcap.cpp
0038     pendingcap.h
0039     capparser.cpp
0040     capparser.h
0041     caparea.cpp
0042     caparea.h
0043     capreference.cpp
0044     capreference.h
0045     reply.cpp
0046     reply.h
0047 )
0048
0049
0050 add_library(KWeatherCore ${kweathercore_LIB_SRCS})
0051 generate_export_header(KWeatherCore BASE_NAME KWeatherCore EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/kweathercore/kweathercore_export.h)
0052 set(kweathercore_BUILD_INCLUDE_DIRS ${KWeatherCore_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR})
0053 target_include_directories(KWeatherCore PUBLIC "$<BUILD_INTERFACE:${kweathercore_BUILD_INCLUDE_DIRS}>")
0054 target_include_directories(KWeatherCore INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KWeatherCore>")
0055
0056 target_link_libraries(KWeatherCore
0057 PUBLIC
0058     Qt6::Core
0059 PRIVATE
0060     Qt6::Network
0061     Qt6::Positioning
0062     KF6::I18n
0063     KF6::I18nLocaleData
0064     KF6::Holidays
0065 )
0066
0067 set_target_properties(KWeatherCore PROPERTIES VERSION ${KWEATHERCORE_VERSION}
0068                                    SOVERSION ${KWEATHERCORE_SOVERSION}
0069                                    EXPORT_NAME KWeatherCore
0070 )
0071
0072 ecm_generate_headers(KWeatherCore_CamelCase_HEADERS
0073     HEADER_NAMES
0074     LocationQuery
0075     LocationQueryReply
0076     LocationQueryResult
0077     DailyWeatherForecast
0078     HourlyWeatherForecast
0079     PendingWeatherForecast
0080     WeatherForecast
0081     WeatherForecastSource
0082     GeoTimezone
0083     CAPAlertInfo
0084     CAPAlertMessage
0085     AlertFeedEntry
0086     AlertManager
0087     PendingAlerts
0088     PendingCAP
0089     CAPParser
0090     CAPArea
0091     CAPNamedValue
0092     CAPReference
0093     Reply
0094
0095     PREFIX KWeatherCore
0096     REQUIRED_HEADERS KWeatherCore_HEADERS
0097 )
0098 install(FILES ${KWeatherCore_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KWeatherCore/KWeatherCore COMPONENT Devel)
0099
0100 install(TARGETS KWeatherCore EXPORT KWeatherCoreTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0101 install(FILES
0102   ${CMAKE_CURRENT_BINARY_DIR}/kweathercore/kweathercore_export.h
0103   ${KWeatherCore_HEADERS}
0104   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KWeatherCore/kweathercore COMPONENT Devel
0105 )
0106
0107 if(BUILD_QCH)
0108     ecm_add_qch(
0109         KWeatherCore_QCH
0110         NAME KWeatherCore
0111         BASE_NAME KWeatherCore
0112         VERSION ${PROJECT_VERSION}
0113         ORG_DOMAIN org.kde
0114         SOURCES # using only public headers, to cover only public API
0115             ${KWeatherCore_HEADERS}
0116         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0117         LINK_QCHS
0118             Qt5Core_QCH
0119         INCLUDE_DIRS
0120             ${kweathercore_BUILD_INCLUDE_DIRS}
0121         BLANK_MACROS
0122             KWEATHERCORE_EXPORT
0123             KWEATHERCORE_DEPRECATED
0124             KWEATHERCORE_DEPRECATED_EXPORT
0125         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0126         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0127         COMPONENT Devel
0128         )
0129 endif()
0130
0131 include(ECMGeneratePriFile)
0132 ecm_generate_pri_file(
0133     BASE_NAME KWeatherCore
0134     LIB_NAME KWeatherCore
0135     DEPS "core"
0136     FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR}/KWeatherCore
0137 )
0138 install(FILES ${PRI_FILENAME}
0139         DESTINATION ${ECM_MKSPECS_INSTALL_DIR})