libraries/kweathercore/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.5)
0002 project(KWeatherCore VERSION "0.8.0")
0003
0004 set(CMAKE_CXX_STANDARD 17)
0005
0006 include(FeatureSummary)
0007
0008 set(REQUIRED_QT_VERSION 6.5.0)
0009 set(KF_DEP_VERSION "5.240.0")
0010
0011 find_package(ECM ${KF_DEP_VERSION}  NO_MODULE)
0012 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://invent.kde.org/frameworks/extra-cmake-modules")
0013 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0014
0015 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0016
0017 include(KDEInstallDirs)
0018 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0019 include(KDECMakeSettings)
0020 include(KDEClangFormat)
0021 include(KDEGitCommitHooks)
0022
0023 include(GenerateExportHeader)
0024
0025 include(ECMSetupVersion)
0026 include(ECMGenerateHeaders)
0027 include(ECMAddQch)
0028
0029 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0030 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0031
0032 ecm_setup_version(PROJECT VARIABLE_PREFIX KWEATHERCORE
0033                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kweathercore_version.h"
0034                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KWeatherCoreConfigVersion.cmake"
0035                         SOVERSION 6)
0036
0037 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core Network Positioning)
0038 find_package(KF6 ${KF_DEP_VERSION} REQUIRED COMPONENTS I18n Holidays)
0039
0040
0041 add_definitions(-DTRANSLATION_DOMAIN=\"kweathercore6\")
0042 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
0043     ki18n_install(po)
0044 endif()
0045 add_definitions(-DQT_DISABLE_DEPRECATED_BEFORE=0x050d00)
0046 add_definitions(-DKF_DISABLE_DEPRECATED_BEFORE_AND_AT=0x054B00)
0047 add_definitions(-DQT_NO_FOREACH)
0048 add_subdirectory(src)
0049
0050 option(BUILD_EXAMPLES "Build example applications" OFF)
0051
0052 if (BUILD_TESTING)
0053     add_subdirectory(autotests)
0054 endif()
0055 if(BUILD_EXAMPLES)
0056     add_subdirectory(examples)
0057 endif()
0058
0059 # create a Config.cmake and a ConfigVersion.cmake file and install them
0060 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KWeatherCore")
0061
0062 if (BUILD_QCH)
0063     ecm_install_qch_export(
0064         TARGETS KWeatherCore_QCH
0065         FILE KWeatherCoreQchTargets.cmake
0066         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0067         COMPONENT Devel
0068     )
0069     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KWeatherCoreQchTargets.cmake\")")
0070 endif()
0071
0072 include(CMakePackageConfigHelpers)
0073
0074 configure_package_config_file(
0075     "${CMAKE_CURRENT_SOURCE_DIR}/KWeatherCoreConfig.cmake.in"
0076     "${CMAKE_CURRENT_BINARY_DIR}/KWeatherCoreConfig.cmake"
0077     INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0078 )
0079
0080 install(FILES
0081             "${CMAKE_CURRENT_BINARY_DIR}/KWeatherCoreConfig.cmake"
0082             "${CMAKE_CURRENT_BINARY_DIR}/KWeatherCoreConfigVersion.cmake"
0083         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0084         COMPONENT Devel
0085 )
0086
0087 install(EXPORT KWeatherCoreTargets
0088         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0089         FILE KWeatherCoreTargets.cmake)
0090
0091 install(FILES
0092     ${CMAKE_CURRENT_BINARY_DIR}/kweathercore_version.h
0093     DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel
0094 )
0095
0096 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0097
0098 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0099 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0100
0101 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0102