libraries/kweathercore/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.5)
0002 set(KF5_VERSION "0.2.0") # handled by release scripts
0003 set(KF5_DEP_VERSION "5.75.0") # handled by release scripts
0004 project(KWeatherCore VERSION ${KF5_VERSION})
0005
0006 set(CMAKE_CXX_STANDARD 17)
0007
0008 include(FeatureSummary)
0009 find_package(ECM ${KF5_DEP_VERSION}  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013
0014 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR})
0015
0016 set(REQUIRED_QT_VERSION 5.12.0)
0017
0018 include(KDEInstallDirs)
0019 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0020 include(KDECMakeSettings)
0021
0022
0023 include(GenerateExportHeader)
0024
0025 include(ECMSetupVersion)
0026 include(ECMGenerateHeaders)
0027 include(ECMAddQch)
0028
0029 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0030 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0031
0032 ecm_setup_version(PROJECT VARIABLE_PREFIX KWEATHERCORE
0033                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kweathercore_version.h"
0034                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5KWeatherCoreConfigVersion.cmake"
0035                         SOVERSION 5)
0036
0037 find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core Network Positioning)
0038 find_package(KF5I18n ${KF5_DEP_VERSION} REQUIRED)
0039
0040
0041 add_definitions(-DTRANSLATION_DOMAIN=\"kweathercore5\")
0042 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
0043     ki18n_install(po)
0044 endif()
0045 add_definitions(-DQT_DISABLE_DEPRECATED_BEFORE=0x050d00)
0046 add_definitions(-DKF_DISABLE_DEPRECATED_BEFORE_AND_AT=0x054B00)
0047 add_definitions(-DQT_NO_FOREACH)
0048 add_subdirectory(src)
0049
0050 option(BUILD_EXAMPLES "Build example applications" OFF)
0051
0052 if (BUILD_TESTING)
0053     add_subdirectory(autotests)
0054 endif()
0055 if(BUILD_EXAMPLES)
0056     add_subdirectory(examples)
0057 endif()
0058
0059 # create a Config.cmake and a ConfigVersion.cmake file and install them
0060 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5KWeatherCore")
0061
0062 if (BUILD_QCH)
0063     ecm_install_qch_export(
0064         TARGETS KF5KWeatherCore_QCH
0065         FILE KF5KWeatherCoreQchTargets.cmake
0066         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0067         COMPONENT Devel
0068     )
0069     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5KWeatherCoreQchTargets.cmake\")")
0070 endif()
0071
0072 include(CMakePackageConfigHelpers)
0073
0074 configure_package_config_file(
0075     "${CMAKE_CURRENT_SOURCE_DIR}/KF5KWeatherCoreConfig.cmake.in"
0076     "${CMAKE_CURRENT_BINARY_DIR}/KF5KWeatherCoreConfig.cmake"
0077     INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0078 )
0079
0080 install(FILES
0081             "${CMAKE_CURRENT_BINARY_DIR}/KF5KWeatherCoreConfig.cmake"
0082             "${CMAKE_CURRENT_BINARY_DIR}/KF5KWeatherCoreConfigVersion.cmake"
0083         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0084         COMPONENT Devel
0085 )
0086
0087 install(EXPORT KF5KWeatherCoreTargets
0088         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0089         FILE KF5KWeatherCoreTargets.cmake
0090         NAMESPACE KF5::)
0091
0092 install(FILES
0093     ${CMAKE_CURRENT_BINARY_DIR}/kweathercore_version.h
0094     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5} COMPONENT Devel
0095 )
0096
0097 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)