libraries/ksanecore/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 #
0003 # SPDX-License-Identifier: BSD-2-Clause
0004
0005 cmake_minimum_required(VERSION 3.16.0)
0006
0007 # KDE Applications version, managed by release script.
0008 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0009 set(RELEASE_SERVICE_VERSION_MINOR "08")
0010 set(RELEASE_SERVICE_VERSION_MICRO "2")
0011 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0012
0013 project(KSaneCore VERSION ${RELEASE_SERVICE_VERSION})
0014
0015 include(FeatureSummary)
0016 set(KF5_VERSION "5.90.0")
0017 find_package(ECM ${KF5_VERSION} REQUIRED NO_MODULE)
0018 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0019 set(CMAKE_MODULE_PATH ${KSaneCore_SOURCE_DIR}/cmake-modules ${ECM_MODULE_PATH})
0020
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024
0025 include(FeatureSummary)
0026 include(ECMSetupVersion)
0027 include(ECMGenerateHeaders)
0028 include(ECMInstallIcons)
0029 include(CMakePackageConfigHelpers)
0030 include(CheckFunctionExists)
0031 include(ECMGenerateExportHeader)
0032 include(ECMQtDeclareLoggingCategory)
0033 include(KDEGitCommitHooks)
0034 include(KDEClangFormat)
0035 include(ECMDeprecationSettings)
0036 if (QT_MAJOR_VERSION STREQUAL "6")
0037     set(QT_REQUIRED_VERSION "6.4.0")
0038     set(KF_MIN_VERSION "5.240.0")
0039     set(KF_MAJOR_VERSION "6")
0040 else()
0041     set(KF_MAJOR_VERSION "5")
0042 endif()
0043
0044 set(ksanecore_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/ksanecore_version.h")
0045 ecm_setup_version(
0046     ${RELEASE_SERVICE_VERSION}
0047     VARIABLE_PREFIX KSANECORE
0048     VERSION_HEADER "${ksanecore_version_header}"
0049     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KSaneCoreConfigVersion.cmake"
0050     SOVERSION 1
0051 )
0052
0053 # Dependencies
0054 set(REQUIRED_QT_VERSION "5.15.2")
0055 # Required Qt5 components to build this framework
0056 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED Core Gui)
0057 # Required KF5 frameworks
0058 find_package(KF${KF_MAJOR_VERSION}I18n ${KF5_VERSION} REQUIRED)
0059
0060 # Check if sane API is available.
0061 find_package(Sane REQUIRED)
0062 message(STATUS "SANE_FOUND:       ${SANE_FOUND}")
0063 message(STATUS "SANE_INCLUDE_DIR: ${SANE_INCLUDE_DIR}")
0064 message(STATUS "SANE_LIBRARY:     ${SANE_LIBRARY}")
0065
0066 ecm_set_disabled_deprecation_versions(QT 6.4
0067     KF 5.101
0068 )
0069
0070 add_subdirectory(src)
0071 if (BUILD_TESTING)
0072     add_subdirectory(autotests)
0073 endif()
0074
0075 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KSaneCore")
0076
0077 configure_package_config_file(
0078     "${CMAKE_CURRENT_SOURCE_DIR}/KSaneCoreConfig.cmake.in"
0079     "${CMAKE_CURRENT_BINARY_DIR}/KSaneCoreConfig.cmake"
0080     INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0081 )
0082
0083 install(FILES
0084     "${CMAKE_CURRENT_BINARY_DIR}/KSaneCoreConfig.cmake"
0085     "${CMAKE_CURRENT_BINARY_DIR}/KSaneCoreConfigVersion.cmake"
0086     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0087     COMPONENT Devel
0088 )
0089
0090 install(FILES
0091     "${ksanecore_version_header}"
0092     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KSaneCore"
0093     COMPONENT Devel
0094 )
0095
0096 install(EXPORT KSaneCoreTargets
0097     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0098     FILE KSaneCoreTargets.cmake
0099     NAMESPACE KSane::
0100 )
0101
0102 ki18n_install(po)
0103
0104 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0105
0106 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)