libraries/ksanecore/CMakeLists.txt

0001 # SPDX-FileCopyrightText: none
0002 #
0003 # SPDX-License-Identifier: BSD-2-Clause
0004
0005 cmake_minimum_required(VERSION 3.16.0)
0006
0007 # KDE Applications version, managed by release script.
0008 set(RELEASE_SERVICE_VERSION_MAJOR "24")
0009 set(RELEASE_SERVICE_VERSION_MINOR "04")
0010 set(RELEASE_SERVICE_VERSION_MICRO "70")
0011 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0012
0013 project(KSaneCore VERSION ${RELEASE_SERVICE_VERSION})
0014
0015 include(FeatureSummary)
0016 set(KF5_VERSION "5.90.0")
0017 find_package(ECM ${KF5_VERSION} REQUIRED NO_MODULE)
0018 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0019 set(CMAKE_MODULE_PATH ${KSaneCore_SOURCE_DIR}/cmake-modules ${ECM_MODULE_PATH})
0020
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024
0025 include(FeatureSummary)
0026 include(ECMSetupVersion)
0027 include(ECMGenerateHeaders)
0028 include(ECMInstallIcons)
0029 include(CMakePackageConfigHelpers)
0030 include(CheckFunctionExists)
0031 include(ECMGenerateExportHeader)
0032 include(ECMQtDeclareLoggingCategory)
0033 include(KDEGitCommitHooks)
0034 include(KDEClangFormat)
0035 include(ECMDeprecationSettings)
0036 if (QT_MAJOR_VERSION STREQUAL "6")
0037     set(QT_REQUIRED_VERSION "6.4.0")
0038     set(KF_MIN_VERSION "5.240.0")
0039     set(KF_MAJOR_VERSION "6")
0040     set(KSANECORE_SUFFFIX "6")
0041 else()
0042     set(KF_MAJOR_VERSION "5")
0043     set(KSANECORE_SUFFFIX "")
0044 endif()
0045
0046 set(ksanecore_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/ksanecore_version.h")
0047 ecm_setup_version(
0048     ${RELEASE_SERVICE_VERSION}
0049     VARIABLE_PREFIX KSANECORE
0050     VERSION_HEADER "${ksanecore_version_header}"
0051     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KSaneCore${KSANECORE_SUFFFIX}ConfigVersion.cmake"
0052     SOVERSION 1
0053 )
0054
0055 # Dependencies
0056 set(REQUIRED_QT_VERSION "5.15.2")
0057 # Required Qt5 components to build this framework
0058 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED Core Gui)
0059 # Required KF5 frameworks
0060 find_package(KF${KF_MAJOR_VERSION}I18n ${KF5_VERSION} REQUIRED)
0061
0062 # Check if sane API is available.
0063 find_package(Sane REQUIRED)
0064 message(STATUS "SANE_FOUND:       ${SANE_FOUND}")
0065 message(STATUS "SANE_INCLUDE_DIR: ${SANE_INCLUDE_DIR}")
0066 message(STATUS "SANE_LIBRARY:     ${SANE_LIBRARY}")
0067
0068 ecm_set_disabled_deprecation_versions(QT 6.4
0069     KF 5.101
0070 )
0071
0072 add_subdirectory(src)
0073 if (BUILD_TESTING)
0074     add_subdirectory(autotests)
0075 endif()
0076
0077 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KSaneCore${KSANECORE_SUFFFIX}")
0078
0079 configure_package_config_file(
0080     "${CMAKE_CURRENT_SOURCE_DIR}/KSaneCoreConfig.cmake.in"
0081     "${CMAKE_CURRENT_BINARY_DIR}/KSaneCore${KSANECORE_SUFFFIX}Config.cmake"
0082     INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0083 )
0084
0085 install(FILES
0086     "${CMAKE_CURRENT_BINARY_DIR}/KSaneCore${KSANECORE_SUFFFIX}Config.cmake"
0087     "${CMAKE_CURRENT_BINARY_DIR}/KSaneCore${KSANECORE_SUFFFIX}ConfigVersion.cmake"
0088     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0089     COMPONENT Devel
0090 )
0091
0092 install(FILES
0093     "${ksanecore_version_header}"
0094     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KSaneCore${KSANECORE_SUFFFIX}"
0095     COMPONENT Devel
0096 )
0097
0098 install(EXPORT KSaneCore${KSANECORE_SUFFFIX}Targets
0099     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0100     FILE KSaneCore${KSANECORE_SUFFFIX}Targets.cmake
0101     NAMESPACE KSane${KSANECORE_SUFFFIX}::
0102 )
0103
0104 ki18n_install(po)
0105
0106 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0107
0108 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)