libraries/kdb/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
0002
0003 # Dependencies
0004 set(REQUIRED_QT_VERSION 5.4.0)
0005 set(REQUIRED_KF5_VERSION 5.45.0)
0006
0007 find_package(ECM ${REQUIRED_KF5_VERSION} REQUIRED NO_MODULE)
0008 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules ${ECM_MODULE_PATH})
0009 include(SetKDbCMakePolicies NO_POLICY_SCOPE)
0010
0011 project(KDb VERSION 3.2.90) # Update this: Alpha = 90, Beta 1 = 91, RC 1 = 94
0012
0013 include(KDbAddTests)
0014 include(KDbAddExamples)
0015 kdb_add_tests(OFF)
0016 kdb_add_examples(OFF)
0017
0018 # ECM
0019 include(KDEInstallDirs)
0020 include(KDECMakeSettings NO_POLICY_SCOPE)
0021 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0022
0023 include(ECMGeneratePriFile)
0024 include(ECMInstallIcons)
0025 include(ECMOptionalAddSubdirectory)
0026 include(ECMPoQmTools)
0027 include(ECMSetupVersion)
0028 include(ECMCoverageOption)
0029 include(ECMSetupQtPluginMacroNames)
0030 include(ECMAddQch)
0031
0032 # Own
0033 include(KDbCreateSharedDataClasses)
0034 include(KDbGenerateHeaders)
0035 include(KDbMacros)
0036
0037 simple_option(BUILD_QCH "Build API documentation in QCH format" OFF)
0038
0039
0040 # Required components to build this framework
0041 # TODO move Widgets-dependent part to a libKDbWidgets
0042 find_package(Qt5 ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED Core Widgets Xml)
0043 find_package(KF5 ${REQUIRED_KF5_VERSION} REQUIRED CoreAddons)
0044 find_package(ICU REQUIRED i18n uc)
0045 set_package_properties(ICU PROPERTIES
0046                        PURPOSE "Required by KDb for unicode-aware string comparisons")
0047
0048 get_git_revision_and_branch()
0049 add_unfinished_features_option()
0050
0051 add_subdirectory(src)
0052 add_subdirectory(tools)
0053
0054 if(BUILD_TESTING)
0055   add_subdirectory(autotests)
0056   add_subdirectory(tests)
0057 endif()
0058
0059 add_custom_target(cppclean
0060     COMMAND ${CMAKE_SOURCE_DIR}/tools/cppclean-kdb.sh ${CMAKE_BINARY_DIR}
0061     COMMENT "Running CPPCLEAN"
0062 )
0063
0064 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/poqm")
0065     ecm_install_po_files_as_qm(poqm)
0066 endif()
0067
0068 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)