3rdparty/ext_sip/CMakeLists.txt

0001 SET(PREFIX_ext_sip "${EXTPREFIX}" )
0002
0003 if(APPLE)
0004     if(NOT Python_FOUND)
0005         SET(Python_EXECUTABLE ${PREFIX_ext_sip}/bin/python3)
0006         if(NOT EXISTS "${Python_EXECUTABLE}")
0007             message("WARNING: using system python3!")
0008             SET(Python_EXECUTABLE python3)
0009         endif()
0010     endif()
0011
0012     ExternalProject_Add( ext_sip
0013         DOWNLOAD_DIR ${EXTERNALS_DOWNLOAD_DIR}
0014         URL https://files.kde.org/krita/build/dependencies/sip-4.19.19.tar.gz
0015         URL_MD5 98111479309dc472410f26080d6d4a88
0016
0017         CMAKE_ARGS -DPYTHON_INCLUDE_DIR=${PREFIX_ext_sip}/lib/Python.framework/Headers
0018         CONFIGURE_COMMAND ${Python_EXECUTABLE} <SOURCE_DIR>/configure.py --deployment-target=10.11
0019             -b ${PREFIX_ext_sip}/bin -d ${PREFIX_ext_sip}/lib/Python.framework/Versions/Current/site-packages/
0020             -e ${PREFIX_ext_sip}/include --sipdir ${PREFIX_ext_sip}/share/sip --target-py-version 3.8 --sip-module PyQt5.sip
0021
0022         # force single-threaded installation to avoid
0023         # race conditions in post-install .py script
0024         INSTALL_COMMAND make -j1 install
0025             # COMMAND ${CMAKE_COMMAND} -E create_symlink ./PyQt5/sip.so ${PREFIX_ext_sip}/lib/Python.framework/Versions/Current/site-packages/sip.so
0026             # COMMAND ${CMAKE_COMMAND} -E create_symlink ./PyQt5/sip.pyi ${PREFIX_ext_sip}/lib/Python.framework/Versions/Current/site-packages/sip.pyi
0027
0028         BUILD_IN_SOURCE 1
0029
0030         UPDATE_COMMAND ""
0031     )
0032 elseif(UNIX)
0033     set(Python_EXECUTABLE ${PREFIX_ext_sip}/bin/python3)
0034     if(NOT EXISTS ${Python_EXECUTABLE})
0035       message("WARNING: using system python3!")
0036       set(Python_EXECUTABLE python3)
0037     endif()
0038
0039     ExternalProject_Add( ext_sip
0040         DOWNLOAD_DIR ${EXTERNALS_DOWNLOAD_DIR}
0041         URL https://pypi.python.org/packages/source/s/sip/sip-6.6.2.tar.gz
0042         URL_HASH SHA256=0e3efac1c5dfd8e525ae57140927df26993e13f58b89d1577c314f4105bfd90d
0043
0044         CONFIGURE_COMMAND ""
0045
0046         BUILD_COMMAND ${CMAKE_COMMAND} -E env
0047             "PYTHONPATH=${KRITA_PYTHONPATH}"
0048             ${Python_EXECUTABLE} <SOURCE_DIR>/setup.py build -j ${SUBMAKE_JOBS}
0049
0050         INSTALL_COMMAND ${CMAKE_COMMAND} -E env
0051             "PYTHONPATH=${KRITA_PYTHONPATH}"
0052             ${Python_EXECUTABLE} <SOURCE_DIR>/setup.py install --skip-build --prefix=${PREFIX_ext_sip} --optimize=1
0053
0054         BUILD_IN_SOURCE 1
0055
0056         UPDATE_COMMAND ""
0057     )
0058 elseif (WIN32)
0059     if(MINGW)
0060         set(_compiler -c mingw32)
0061     elseif(MSVC)
0062         set(_compiler -c msvc)
0063     endif()
0064
0065     krita_to_native_path("${PREFIX_ext_sip}" _sip_prefix)
0066     krita_to_native_path("${KRITA_PYTHONPATH}" _krita_pythonpath)
0067     string(TOLOWER ${_krita_pythonpath} _krita_pythonpath)
0068     krita_to_native_environment_path_list("${_krita_pythonpath}" _krita_pythonpath)
0069
0070     ExternalProject_Add( ext_sip
0071         DOWNLOAD_DIR ${EXTERNALS_DOWNLOAD_DIR}
0072         URL https://pypi.python.org/packages/source/s/sip/sip-6.6.2.tar.gz
0073         URL_HASH SHA256=0e3efac1c5dfd8e525ae57140927df26993e13f58b89d1577c314f4105bfd90d
0074
0075         CONFIGURE_COMMAND ""
0076
0077         BUILD_COMMAND ${CMAKE_COMMAND} -E env
0078             PYTHONPATH=${_krita_pythonpath}
0079             SETUPTOOLS_USE_DISTUTILS=local
0080             ${Python_EXECUTABLE} <SOURCE_DIR>/setup.py build -j ${SUBMAKE_JOBS} ${_compiler}
0081
0082         # HACK: Create lib\site-packages before installing
0083         # See e.g. https://access.redhat.com/errata/RHBA-2020:4437
0084         INSTALL_COMMAND ${CMAKE_COMMAND} -E make_directory ${_sip_prefix}\\lib\\site-packages
0085             COMMAND ${CMAKE_COMMAND} -E env
0086                 PYTHONPATH=${_krita_pythonpath}
0087                 SETUPTOOLS_USE_DISTUTILS=local
0088                 ${Python_EXECUTABLE} <SOURCE_DIR>/setup.py install --skip-build --prefix=${_sip_prefix} --optimize=1 --install-scripts=${_sip_prefix}\\bin
0089
0090         BUILD_IN_SOURCE 1
0091
0092         UPDATE_COMMAND ""
0093     )
0094
0095     if (MINGW)
0096         ExternalProject_Add_Step(ext_sip
0097             wheel_update_setuptools
0098             COMMAND ${CMAKE_COMMAND} -E env
0099             PYTHONPATH=${_krita_pythonpath}
0100             ${Python_EXECUTABLE} -m pip install -U pip setuptools>==59.8.0
0101                 COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/../ext_python/sitecustomize.py ${KRITA_PYTHONPATH}
0102
0103             DEPENDERS build
0104         )
0105         message(STATUS "Using mingw, Will deploy workaround for setuptools.")
0106         ExternalProject_Add_Step(ext_sip
0107             distutils_system_mod
0108             COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/../ext_python/_distutils_system_mod.py ${KRITA_PYTHONPATH}
0109
0110             DEPENDERS build
0111         )
0112     endif()
0113 endif()
0114